provider "aws" {
  region = var.aws_region
}

# Caller Identity
data "aws_caller_identity" "current" {}

# S3 backend
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/performance-rights/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "prs_s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=2.5.5"

  env                 = var.environment
  bucket_name         = var.bucket_name
  application_family  = var.application_family

  apply_server_side_encryption_by_default = {

    sse_algorithm = "AES256"
  }
}

resource "aws_iam_policy" "prs_usage_policy" {
  name   = "S3-prod-performance-rights-usage-policy"
  policy = data.aws_iam_policy_document.prs_usage_policy.json
}

data "aws_iam_policy_document" "prs_usage_policy" {
  statement {
    effect = "Allow"
    actions = [
      "s3:ListBucket",
      "s3:GetBucketLocation"
    ]
    resources = [module.prs_s3_bucket.s3_bucket_arn_output]
  }

  statement {
    effect = "Allow"
    actions = [
      "s3:GetObject",
      "s3:PutObject",
      "s3:DeleteObject"
    ]
    resources = ["${module.prs_s3_bucket.s3_bucket_arn_output}/*"]
  }
}