provider "aws" {
  region = var.region
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/product-physical-delivery/bucket/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.0.3"

  env                 = var.environment
  bucket_name         = "delivery"
  acceleration_status = "Enabled"
  application_family  = var.application_family
  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
  s3_read_only_policy = true

  # no lifecycle policy for now
}

data "aws_iam_policy_document" "physical_delivery_bucket_rwd_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "s3:ListBucket",
      "s3:GetBucketLocation"
    ]

    resources = [
      module.s3_bucket.s3_bucket_arn_output
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "s3:GetObject",
      "s3:PutObject",
      "s3:DeleteObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/physical/*",
    ]
  }
}

resource "aws_iam_policy" "physical_bucket_rwd_policy" {
  name        = "S3-${module.s3_bucket.s3_bucket_name_output}-physical-RWD"
  description = "RWD access to /physical folder in qa-delivery bucket"
  policy      = data.aws_iam_policy_document.physical_delivery_bucket_rwd_policy_document.json
}

resource "aws_iam_policy" "physical_delivery_bucket_rwd_policy" {
  name        = "S3-${module.s3_bucket.s3_bucket_name_output}-physical-delivery-RWD"
  description = "RWD access to /physical folder in qa-delivery bucket"
  policy      = data.aws_iam_policy_document.physical_delivery_bucket_rwd_policy_document.json
}