provider "aws" {
  region = var.region
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/product-physical-delivery/delivery-step-function/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

#  Physical Delivery Step Function.

# reference to metadata generator lambda.
data "aws_lambda_function" "lambda_metadata_generator_metadata" {
  function_name = "${var.environment}-${var.metadata_generator_lambda_name}"
}

# reference to product hydrator lambda.
data "aws_lambda_function" "lambda_phy_delivery_product_hydrator" {
  function_name = "${var.environment}-${var.product_hydrator_lambda_name}"
}

# reference to order finalizer lambda.
data "aws_lambda_function" "lambda_phy_delivery_order_finalizer" {
  function_name = "${var.environment}-${var.order_finalizer_lambda_name}"
}

# Assume role policy for state machine.
data "aws_iam_policy_document" "assume_role_for_phy_delivery_state_machine_policy" {
  statement {
    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type = "Service"

      identifiers = [
        "states.${var.region}.amazonaws.com",
      ]
    }
  }
}

# States role for lambda invocation.
resource "aws_iam_role" "invoke_phy_delivery_lambdas_from_state_machine" {
  name               = "${var.environment}-physical-delivery-invoke-lambdas-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_for_phy_delivery_state_machine_policy.json
}

# Policy that gives the state machine role permission to invoke lambdas.
data "aws_iam_policy_document" "invoke_phy_delivery_lambdas_policy_document" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      data.aws_lambda_function.lambda_phy_delivery_product_hydrator.arn,
      data.aws_lambda_function.lambda_metadata_generator_metadata.arn,
      data.aws_lambda_function.lambda_phy_delivery_order_finalizer.arn,
    ]
  }
}

resource "aws_iam_policy" "invoke_phy_delivery_lambdas_policy" {
  name   = "Lambda-${var.environment}-physical-delivery-invoke-lambdas-policy"
  policy = data.aws_iam_policy_document.invoke_phy_delivery_lambdas_policy_document.json
}

resource "aws_iam_role_policy_attachment" "invoke_phy_delivery_lambdas_role_policy_attachment" {
  for_each = toset([
    aws_iam_policy.invoke_phy_delivery_lambdas_policy.arn,
    aws_iam_policy.invoke_phy_delivery_state_machine_policy.arn,
  ])
  role       = aws_iam_role.invoke_phy_delivery_lambdas_from_state_machine.id
  policy_arn = each.key

}

# State machine.
data "template_file" "phy_delivery_state_machine_definition" {
  template = file("${path.module}/physical_delivery_workflow.json")

  vars = {
    # add all lambda variables here.
    product_hydrator_lambda_arn   = data.aws_lambda_function.lambda_phy_delivery_product_hydrator.arn,
    metadata_generator_lambda_arn = data.aws_lambda_function.lambda_metadata_generator_metadata.arn,
    order_finalizer_lambda_arn    = data.aws_lambda_function.lambda_phy_delivery_order_finalizer.arn,
  }
}

resource "aws_sfn_state_machine" "phy_delivery_state_machine" {
  name       = "${var.environment}-${var.phy_delivery_state_machine_name}"
  role_arn   = aws_iam_role.invoke_phy_delivery_lambdas_from_state_machine.arn
  definition = data.template_file.phy_delivery_state_machine_definition.rendered

  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.phy_delivery_state_machine_name
    terraformed        = true
  }

  tracing_configuration {
    enabled = true
  }
}

# Invoke Step Function Policy
data "aws_iam_policy_document" "invoke_phy_delivery_state_machine_policy_doc" {
  statement {
    actions = [
      "states:StartExecution",
      "states:ListExecutions",
    ]

    resources = [
      aws_sfn_state_machine.phy_delivery_state_machine.arn
    ]
  }
}

resource "aws_iam_policy" "invoke_phy_delivery_state_machine_policy" {
  name        = "StepFunctions-${var.environment}-${var.phy_delivery_state_machine_name}-InvokeOnly"
  description = "Invoke Physical Delivery state machine"
  policy      = data.aws_iam_policy_document.invoke_phy_delivery_state_machine_policy_doc.json
}