module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/graphql-publishing/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

data "aws_iam_policy" "input_bucket_readonly_policy" {
  name = "S3-${var.environment}-publishing-compositions-read-only"
}

data "aws_sfn_state_machine" "changelog_report_state_machine" {
  name = "${var.environment}-publishing-compositions-changelog-report"
}

data "aws_iam_policy" "invoke_changelog_report_state_machine_policy" {
  name = "StepFunctions-${var.environment}-publishing-compositions-changelog-report-StartExecution"
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

module "graphql_publishing_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.1.0"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  aws_region         = var.region
  commit_sha         = "latest"
  container_port     = "8080"
  task_type          = "web_service"
  desired_task_count = 2
  task_cpu           = 2048
  task_memory        = 4096
  maximum_capacity   = 4
  minimum_capacity   = 2

  vpc_id                        = module.vpc_info.vpc_id
  https_listener_certificate_id = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]

  fargate_service_subnets = var.vpc_subnet_ids

  load_balancer_subnets = var.vpc_subnet_ids

  application_family = var.application_family

  iam_managed_policy_attachments = [
    data.aws_iam_policy.invoke_changelog_report_state_machine_policy.arn,
    data.aws_iam_policy.input_bucket_readonly_policy.arn,
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      NODE_ENV = var.environment
    },
    {
      APOLLO_ENGINE_SCHEMA_TAG = var.environment
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
    {
      CACHE_USE_REDIS = "false"
    },
    {
      APOLLO_INTROSPECTION = "false"
    },
    {
      APOLLO_PLAYGROUND = "false"
    },
    {
      DD_LOGS_INJECTION = true
    },
    {
      NEO4J_URL = var.neo4j_url
    },
    {
      KSQL_URL = var.ksql_url
    },
    {
      SNOWFLAKE_SCHEMA = var.environment
    },
    {
      SNOWFLAKE_ROLE = var.snowflake_role
    },
    {
      MYSQL_CHANGELOG_USERNAME = var.mysql_changelog_username
    },
    {
      MYSQL_CHANGELOG_DB_NAME = var.mysql_changelog_db_name
    },
    {
      MYSQL_CHANGELOG_HOSTNAME = "${var.environment}-${var.mysql_changelog_hostname}"
    },
    {
      MYSQL_CHANGELOG_RW_MAX_CONNECTIONS = var.mysql_changelog_rw_connections
    },
    {
      UPLOAD_BUCKET = "${var.environment}-publishing-compositions"
    },
    {
      S3_SIGNED_URL_EXPIRY = var.s3_signed_url_expiry
    },
    {
      CHANGELOG_REPORT_STEP_FN_ARN = data.aws_sfn_state_machine.changelog_report_state_machine.arn
    },
  ]

  secrets = [
    {
      SENTRY_DSN = "${var.environment}/${var.service_name}/SENTRY_DSN"
    },
    {
      NEO4J_USER = "${var.environment}/${var.service_name}/NEO4J_USER"
    },
    {
      NEO4J_PASSWORD = "${var.environment}/${var.service_name}/NEO4J_PASSWORD"
    },
    {
      NEO4J_AURA_URL = "${var.environment}/${var.service_name}/NEO4J_AURA_URL"
    },
    {
      NEO4J_AURA_USERNAME = "${var.environment}/${var.service_name}/NEO4J_AURA_USERNAME"
    },
    {
      NEO4J_AURA_PASSWORD = "${var.environment}/${var.service_name}/NEO4J_AURA_PASSWORD"
    },
    {
      SPLIT_API_KEY = "${var.environment}/${var.service_name}/SPLIT_API_KEY"
    },
    {
      KSQL_CREDS = "${var.environment}/${var.service_name}/KSQL_CREDS"
    },
    {
      SNOWFLAKE_USER = "${var.environment}/${var.service_name}/SNOWFLAKE_USER"
    },
    {
      SNOWFLAKE_PASSWORD = "${var.environment}/${var.service_name}/SNOWFLAKE_PASSWORD"
    },
    {
      SNOWFLAKE_KEY_PASSPHRASE = "${var.environment}/${var.service_name}/SNOWFLAKE_KEY_PASSPHRASE"
    },
    {
      SNOWFLAKE_PRIVATE_KEY = "${var.environment}/${var.service_name}/SNOWFLAKE_PRIVATE_KEY"
    },
    {
      MYSQL_CHANGELOG_PASSWORD = "${var.environment}/${var.service_name}/MYSQL_CHANGELOG_PASSWORD"
    }
  ]
}

module "graphql_publishing_sentry_module" {
  source             = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"
  service_name       = "graphql-publishing"
  environment        = var.environment
  teams              = [var.environment]
  platform           = "node"
  application_family = var.application_family
}

module "graphql_publishing_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.4"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  notification_endpoints            = "@slack-publishing-alerts @slack-graphql"
  datadog_service_type              = "${var.service_name}-graphql"
  datadog_service_name              = "graphql.execute"
  service_4xx_monitor_enabled       = true
  service_5xx_monitor_enabled       = true
  application_family                = var.application_family
  escalation_notification_endpoints = "@slack-publishing-alerts"
}