module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/royalty_accounting/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

data "aws_iam_policy_document" "s3_bucket_read_write_policy" {
  statement {
    actions = [
      "s3:AbortMultipartUpload",
      "s3:DeleteObject",
      "s3:GetBucketLocation",
      "s3:GetBucketObjectLockConfiguration",
      "s3:GetBucketVersioning",
      "s3:GetLifecycleConfiguration",
      "s3:GetObject",
      "s3:GetObjectAcl",
      "s3:GetObjectLegalHold",
      "s3:GetObjectRetention",
      "s3:GetObjectTorrent",
      "s3:GetObjectVersion",
      "s3:GetObjectVersionAcl",
      "s3:GetObjectVersionTorrent",
      "s3:GetReplicationConfiguration",
      "s3:ListBucket",
      "s3:ListBucketMultipartUploads",
      "s3:ListBucketVersions",
      "s3:ListMultipartUploadParts",
      "s3:PutObject",
      "s3:PutObjectAcl"
    ]
    resources = [
      "${module.s3_prod_abacus_static_data_bucket.s3_bucket_arn_output}/",
      "${module.s3_prod_abacus_static_data_bucket.s3_bucket_arn_output}/*",
      module.s3_prod_abacus_static_data_bucket.s3_bucket_arn_output,
    ]
  }
}

data "aws_secretsmanager_secret" "rds_master_username" {
  name = "${var.environment}/royalty_accounting/rds_master_username"
}

data "aws_secretsmanager_secret_version" "rds_master_username" {
  secret_id = data.aws_secretsmanager_secret.rds_master_username.id
}

data "aws_secretsmanager_secret" "rds_master_password" {
  name = "${var.environment}/royalty_accounting/rds_master_password"
}

data "aws_secretsmanager_secret_version" "rds_master_password" {
  secret_id = data.aws_secretsmanager_secret.rds_master_password.id
}

data "aws_route53_zone" "orchard" {
  zone_id = var.route53_zone_id
}

data "aws_route53_zone" "networking_route53_zone" {
  provider = aws.networking
  name     = "theorchard.io"
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment        = var.environment
  service_name       = "royalty_accounting"
  secret_name        = each.value
  application_family = var.application_family
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.0.4"
  
  environment = var.environment
}

resource "aws_kms_key" "kms_key" {
  description             = "alias/prod-royalty-accounting-cmk-rds"
  enable_key_rotation     = true
  policy                  = data.aws_iam_policy_document.kms_policy.json
  tags                    = merge(
    module.default_tags.tags,
    {
      allow_rds_refresh = true
    }
  )
}

resource "aws_kms_alias" "kms_alias" {
  name          = "alias/${var.environment}-${var.service_name}-cmk-rds"
  target_key_id = aws_kms_key.kms_key.key_id
}

data "aws_iam_policy_document" "kms_policy" {
  # checkov:skip=CKV_AWS_109:It is a KMS key policy, so it applies only to a specific key.
  # checkov:skip=CKV_AWS_111:Same as above.

  # Statement from default KMS key policy
  statement {
    effect = "Allow"

    principals {
      type        = "AWS"
      identifiers = ["arn:aws:iam::${data.aws_caller_identity.current.account_id}:root"]
    }

    actions   = ["kms:*"]
    resources = ["*"]
  }

  statement {
    sid    = "Allow share CMK with account 079637511089"
    effect = "Allow"

    principals {
      type        = "AWS"
      identifiers = ["arn:aws:iam::079637511089:root"]
    }

    actions = [
      "kms:ReEncrypt*",
      "kms:GenerateDataKey*",
      "kms:Encrypt*",
      "kms:Describe*",
      "kms:Decrypt*",
      "kms:CreateGrant"
    ]
    resources = ["*"]
  }

  statement {
    sid   = "Allow share CMK with account 103233932089"
    effect = "Allow"

    principals {
      type        = "AWS"
      identifiers = ["arn:aws:iam::103233932089:root"]
    }

    actions = [
      "kms:ReEncrypt*",
      "kms:GenerateDataKey*",
      "kms:Encrypt*",
      "kms:Describe*",
      "kms:Decrypt*",
      "kms:CreateGrant"
    ]
    resources = ["*"]
  }

  statement {
    sid   = "Allow share CMK with account 989790945997"
    effect = "Allow"

    principals {
      type        = "AWS"
      identifiers = ["arn:aws:iam::989790945997:root"]
    }

    actions = [
      "kms:ReEncrypt*",
      "kms:GenerateDataKey*",
      "kms:Encrypt*",
      "kms:Describe*",
      "kms:Decrypt*",
      "kms:CreateGrant"
    ]
    resources = ["*"]
  }
}

module "royalty_accounting_rds" {
  source                                    = "git@github.com:theorchard/terraform-rds.git//?ref=6.6.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                               = var.environment
  service_name                              = var.service_name
  application_family                        = var.application_family
  rds_cluster_instance_class                = "db.r6g.large"
  rds_cluster_instance_count                = "1"
  rds_master_username                       = data.aws_secretsmanager_secret_version.rds_master_username.secret_string
  rds_master_password                       = data.aws_secretsmanager_secret_version.rds_master_password.secret_string
  rds_availability_zones                    = ["us-east-1a", "us-east-1c"]
  rds_db_subnet_group_name                  = "prod-orchard-private-subnet-group"
  rds_db_cluster_parameter_group_name       = var.rds_db_cluster_parameter_group_name
  rds_cluster_instance_parameter_group_name = "default.aurora-mysql8.0"
  rds_performance_insights_enabled          = true
  additional_tags                           = var.additional_tags
  rds_engine_version                        = "8.0.mysql_aurora.3.08.2"
  custom_kms_key_enabled                    = false
  rds_ingress_prefix_list_names             = ["shared-orcd-jump-box-private-subnet-prefix-list"]
  vpc_id                                    = module.vpc_info.vpc_id
  route53_zone_id                           = var.route53_zone_id
  networking_route53_zone_id                = data.aws_route53_zone.networking_route53_zone.id
  custom_cmk_key_arn                        = "arn:aws:kms:us-east-1:437795906767:key/955abc53-f34e-475a-840f-ecda67626398"
  account_ids = [
    "103233932089", # dev
    "079637511089", # backup
    "989790945997"  # qa-accounting
  ]
}

module "s3_prod_abacus_static_data_bucket" {
  source              = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.12.1"
  env                 = var.environment
  bucket_name         = "abacus-static-data"
  kms_key_enabled     = false
  s3_read_only_policy = true
  application_family  = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
}

resource "aws_iam_policy" "royalty_accounting_prod_snowflake_stage_iam_user" {
  name   = "royalty_accounting_prod_snowflake_stage_policy"
  policy = data.aws_iam_policy_document.s3_bucket_read_write_policy.json
}

# IAM user for s3.
resource "aws_iam_user" "royalty_accounting_iam_user" {
  name = "${var.environment}-${var.service_name}"
  tags = {
    terraformed = true
    role        = "service-user"
  }
}

resource "aws_iam_user_policy_attachment" "royalty_accounting_prod_snowflake_stage_s3" {
  user       = aws_iam_user.royalty_accounting_iam_user.name
  policy_arn = aws_iam_policy.royalty_accounting_prod_snowflake_stage_iam_user.arn
}

resource "aws_iam_group_policy_attachment" "royalty_accounting_more_prod_snowflake_stage_s3" {
  group      = "royalty-accounting-more"
  policy_arn = "arn:aws:iam::${data.aws_caller_identity.current.account_id}:policy/S3-${var.environment}-abacus-static-data-read-only"
}

module "rds_dashboard" {
  source             = "git@github.com:theorchard/terraform-datadog.git//modules/rds?ref=6.10.9"
  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family
  teams              = ["abacus"]

  notification_endpoints            = var.monitor_notification_endpoint
  escalation_notification_endpoints = var.monitor_notification_endpoint
}

# Create IAM user for db-deployment
resource "aws_iam_user" "royalty_accounting_db_deploy_prod_iam_user" {
  name = "${var.environment}-${var.service_name}-db-deploy"
  tags = {
    terraformed = true
    role        = "service-user"
  }
}

data "aws_iam_policy_document" "prod_db_creds_read_only_policy_document" {
  statement {
    actions = [
      "s3:GetBucketLocation",
      "s3:GetObject"
    ]
    resources = [
      "arn:aws:s3:::nickelback/db-deploy/${var.environment}/royalty_accounting/db.properties"
    ]
  }

  statement {
    actions = [
      "ecr:GetAuthorizationToken",
      "ecr:BatchCheckLayerAvailability",
      "ecr:GetDownloadUrlForLayer",
      "ecr:GetRepositoryPolicy",
      "ecr:DescribeRepositories",
      "ecr:ListImages",
      "ecr:DescribeImages",
      "ecr:BatchGetImage",
      "ecr:GetLifecyclePolicy",
      "ecr:GetLifecyclePolicyPreview",
      "ecr:ListTagsForResource",
      "ecr:DescribeImageScanFindings"
    ]

    resources = [
      "arn:aws:ecr:*:${data.aws_caller_identity.current.account_id}:repository/royalties-liquibase-runner",
      "arn:aws:ecr:*:${data.aws_caller_identity.current.account_id}:repository/docker-parent-images"
    ]
  }

  statement {
    actions = [
      "ecr:GetAuthorizationToken"
    ]

    resources = [
      "*",
    ]
  }
}

resource "aws_iam_policy" "prod_db_creds_read_only_policy" {
  name   = "${var.environment}-royalty-accounting-database-creds-policy"
  policy = data.aws_iam_policy_document.prod_db_creds_read_only_policy_document.json
}

# Attach IAM policy to IAM user
resource "aws_iam_user_policy_attachment" "prod_db_creds_read_only_policy_attachment" {
  user       = aws_iam_user.royalty_accounting_db_deploy_prod_iam_user.name
  policy_arn = aws_iam_policy.prod_db_creds_read_only_policy.arn
}

# Attach existing IAM policies to IAM user.
data "aws_iam_policy" "s3_royalties_sales_files_rw_policy" {
  name = "S3-${var.environment}-royalties-sales-files-RW"
}

resource "aws_iam_user_policy_attachment" "royalty_accounting_use_s3_royalties_sales_files_rw_policy_attachemt" {
  user       = aws_iam_user.royalty_accounting_iam_user.name
  policy_arn = data.aws_iam_policy.s3_royalties_sales_files_rw_policy.arn
}