module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/royaltyshare-awal-statements-uploader/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

resource "aws_iam_user" "uploader" {
  name = "${var.environment}-${var.service_name}"

  tags = {
    role = "service-user"
  }
}

data "aws_iam_policy" "statement_attachments_rw" {
  name = "S3-prod-orcdbucket_prod-statement-attachments-RW"
}

resource "aws_iam_user_policy_attachment" "statement_attachments_rw" {
  user       = aws_iam_user.uploader.name
  policy_arn = data.aws_iam_policy.statement_attachments_rw.arn
}

# Cross-account role assumed by the rpsapp20 instance profile in the royaltyshare
# account. This lets the upload script authenticate via the instance role instead of
# the long-lived access keys of the aws_iam_user.uploader service user above.
data "aws_iam_policy_document" "uploader_assume_role" {
  statement {
    effect  = "Allow"
    actions = ["sts:AssumeRole"]

    principals {
      type        = "AWS"
      identifiers = ["arn:aws:iam::${var.royaltyshare_account_id}:role/${var.rpsapp20_role_name}"]
    }
  }
}

resource "aws_iam_role" "uploader" {
  name               = "${var.environment}-${var.service_name}"
  assume_role_policy = data.aws_iam_policy_document.uploader_assume_role.json

  tags = {
    role = "service-role"
  }
}

resource "aws_iam_role_policy_attachment" "statement_attachments_rw" {
  role       = aws_iam_role.uploader.name
  policy_arn = data.aws_iam_policy.statement_attachments_rw.arn
}