provider "aws" {
  region = var.aws_region
}

data "aws_caller_identity" "current" {}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/salesforce/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "multiple_secrets_with_same_settings" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.0.2"
  for_each = toset(var.sforce_secrets)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

# Jenkins assume role policy document
data "aws_iam_policy_document" "salesforce_components_gda_deploy_role_policy_document" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

# Salesforce components gda deploy role
resource "aws_iam_role" "salesforce_components_gda_deploy_service_role" {
  name               = "${var.environment}-salesforce-components-gda_deploy-role"
  assume_role_policy = data.aws_iam_policy_document.salesforce_components_gda_deploy_role_policy_document.json
  tags = {
    environment        = var.environment
    application_family = var.application_family
    service_name       = var.service_name
    terraformed        = "true"
  }
}

# Salesforce_components_gda_deploy secrets manager policy document
data "aws_iam_policy_document" "salesforce_components_gda_deploy_secrets_policy_document" {
  statement {
    effect = "Allow"

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/*",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/",
    ]

    actions = [
      "secretsmanager:ListSecretVersionIds",
      "secretsmanager:GetSecretValue",
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:DescribeSecret",
    ]
  }

  statement {
    effect    = "Allow"
    resources = ["*"]
    actions   = ["secretsmanager:GetRandomPassword"]
  }
}

# Salesforce_components_gda_deploy secrets manager policy
resource "aws_iam_policy" "salesforce_components_gda_deploy_secrets_policy" {
  name   = "SecretsManager-${var.environment}-salesforce-components-gda-deploy-policy"
  policy = data.aws_iam_policy_document.salesforce_components_gda_deploy_secrets_policy_document.json

  tags = {
    environment        = var.environment
    application_family = var.application_family
    service_name       = var.service_name
    terraformed        = "true"
  }
}

# Attach Salesforce_components_gda_deploy secrets manager policy to service role
resource "aws_iam_role_policy_attachment" "salesforce_components_gda_deploy_service_role_attachment" {
  role       = aws_iam_role.salesforce_components_gda_deploy_service_role.name
  policy_arn = aws_iam_policy.salesforce_components_gda_deploy_secrets_policy.arn
}