module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = "${var.service_name}-${var.lambda_github_public_repo_audit_name}"
}

provider "aws" {
  region = var.region

  default_tags {
    tags = module.default_tags.tags
  }
}

data "aws_caller_identity" "current" {}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/security-scripts/github_public_repo_audit/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

module "sentry_github_public_repo_audit" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  service_name       = "lambda-${var.lambda_github_public_repo_audit_name}"
  application_family = var.application_family
  teams              = [var.environment]
}

module "lambda_secrets" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"

  environment        = var.environment
  service_name       = "${var.service_name}-${var.lambda_github_public_repo_audit_name}"
  secret_name        = var.secret_name
  application_family = var.application_family
}

data "aws_iam_policy_document" "ses_email_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      "arn:aws:ses:us-east-1:${data.aws_caller_identity.current.account_id}:identity/${var.ses_email_sender}"
    ]
    actions = [
      "ses:SendEmail",
      "ses:SendRawEmail"
    ]
  }
}

resource "aws_iam_policy" "ses_email_policy" {
  name        = "${var.environment}-${var.service_name}-${var.lambda_github_public_repo_audit_name}-SES-policy"
  description = "${var.service_name}-${var.lambda_github_public_repo_audit_name} SES policy."
  policy      = data.aws_iam_policy_document.ses_email_policy_document.json
}

module "lambda_github_public_repo_audit" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=4.1.0"

  environment                 = var.environment
  application_family          = var.application_family
  use_container_image         = true
  lambda_name                 = "${var.service_name}-${var.lambda_github_public_repo_audit_name}"
  lambda_description          = "Scan github organization for any new public repo created."
  lambda_function_memory_size = var.lambda_function_memory_size
  datadog_advanced_enabled    = var.datadog_advanced_enabled
  datadog_enabled             = var.datadog_enabled
  cloudwatch_event_enabled    = true
  cloudwatch_event_rules = [
    {
      name     = "lambda-${var.lambda_github_public_repo_audit_name}"
      schedule = "rate(1 hour)"
    },
  ]
  iam_managed_policy_attachments = [
    aws_iam_policy.ses_email_policy.arn,
  ]

  lambda_function_environment_variables = {
    ENVIRONMENT                   = var.environment
    SENTRY_DSN                    = module.sentry_github_public_repo_audit.sentry_key_dsn_public_output
    GITHUB_ORG                    = var.github_org
    SES_EMAIL_SENDER              = var.ses_email_sender
    SES_EMAIL_RECIPIENTS          = var.ses_email_recipients
    GITHUB_PUBLIC_REPO_TO_EXCLUDE = var.github_public_repo_to_exclude
  }

  lambda_function_timeout = var.lambda_function_timeout
  vpc_enabled             = true
  vpc_id                  = module.vpc_info.vpc_id
  vpc_subnet_ids          = module.vpc_info.default_private_subnet_ids
}