# Provider determines the method (AWS) and some basic provider properties
provider "aws" {
  region = var.region
}

# Caller Identity
data "aws_caller_identity" "current" {}

# Terraform backends cannot contain interpolations - of the form ${var.environment}-${var.service_name}-state
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/security-scripts/terraform.tfstate"
    region  = "us-east-1"
    encrypt = true
  }
}

# Assume role policy used by Jenkins pipeline agent role
data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/${var.environment}-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

# Jenkins pipeline agent will assume this role in order to access aws resources used by the script.
resource "aws_iam_role" "security_scripts_jenkins_role" {
  name               = "${var.environment}-security-scripts-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

module "pde_audit_review_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.0.3"

  bucket_name         = "pde-audit-review"
  env                 = var.environment
  application_family  = var.application_family
  s3_read_only_policy = true

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  lifecycle_rules_abort_incomplete_multipart_upload_days = [
    {
      prefix  = ""
      enabled = true
      days    = 7
    }
  ]
}

data "aws_iam_policy_document" "pde_audit_review_s3_read_write_only_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "s3:GetObject",
      "s3:PutObject",
      "s3:CreateMultipartUpload",
      "s3:UploadPart",
      "s3:AbortMultipartUpload",
      "s3:CompleteMultipartUpload",
    ]

    resources = [
      "${module.pde_audit_review_bucket.s3_bucket_arn_output}/*",
    ]
  }
}

resource "aws_iam_policy" "pde_audit_review_s3_read_write_only_policy" {
  name        = "S3-${module.pde_audit_review_bucket.s3_bucket_name_output}-RW"
  description = "Read Write access to ${module.pde_audit_review_bucket.s3_bucket_name_output} bucket"
  policy      = data.aws_iam_policy_document.pde_audit_review_s3_read_write_only_policy_document.json
}