# Provider determines the method (AWS) and some basic provider properties
provider "aws" {
  region = var.region
}

# Caller Identity
data "aws_caller_identity" "current" {}

# Terraform backends cannot contain interpolations - of the form ${var.environment}-${var.service_name}-state
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/quarterly-oa-account-review/terraform.tfstate"
    region  = "us-east-1"
    encrypt = true
  }
}

module "multiple_secrets_with_same_settings" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.0.4"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
}

data "aws_iam_policy_document" "quarterly_oa_account_review_document" {
  statement {
    effect = "Allow"
    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/*",
    ]

    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds",
    ]
  }
}

# Give the lambda permission to get secret
resource "aws_iam_policy" "quarterly_oa_account_review_secret_policy" {
  name        = "Secretsmanager-${var.environment}-quarterly-oa-account-review-policy"
  description = "quarterly oa account review secret policy"
  policy      = data.aws_iam_policy_document.quarterly_oa_account_review_document.json
}

data "aws_iam_role" "security_scripts_role" {
  name = "${var.environment}-security-scripts-role"
}

data "aws_iam_policy" "s3_pde_audit_review_policy" {
  name = "S3-${var.environment}-pde-audit-review-RW"
}

# Attach policies to Jenkins role.
resource "aws_iam_role_policy_attachment" "quarterly_oa_account_review_policies_attachment" {
  for_each = toset([
    aws_iam_policy.quarterly_oa_account_review_secret_policy.arn,
    data.aws_iam_policy.s3_pde_audit_review_policy.arn,
  ])
  role       = data.aws_iam_role.security_scripts_role.id
  policy_arn = each.key
}