data "aws_iam_policy_document" "assume_role" {
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"

    principals {
      type        = "AWS"
      identifiers = [snowflake_storage_integration_aws.integration.describe_output[0].iam_user_arn]
    }

    condition {
      test     = "StringEquals"
      variable = "sts:ExternalId"
      values   = [snowflake_storage_integration_aws.integration.describe_output[0].external_id]
    }
  }
}

# Read-only access, scoped to the neo4j_hfr prefix of the shared prod bucket.
data "aws_iam_policy_document" "s3_read" {
  statement {
    sid       = "ReadObjects"
    actions   = ["s3:GetObject", "s3:GetObjectVersion"]
    resources = ["arn:aws:s3:::${var.s3_bucket}/${var.s3_prefix}*"]
  }

  statement {
    sid       = "ListBucket"
    actions   = ["s3:ListBucket", "s3:GetBucketLocation"]
    resources = ["arn:aws:s3:::${var.s3_bucket}"]
  }
}

resource "aws_iam_role" "snowflake_integration_role" {
  name               = local.snowflake_integration_role_name
  assume_role_policy = data.aws_iam_policy_document.assume_role.json
}

resource "aws_iam_role_policy" "s3_read" {
  name   = "${var.environment}-${var.application_family}-neo4j-hfr-read-policy"
  role   = aws_iam_role.snowflake_integration_role.id
  policy = data.aws_iam_policy_document.s3_read.json
}