module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "snowflake" {
  account_name = "delphi"
  role         = "PROD_ATLANTIS"
  preview_features_enabled = [
    "snowflake_stage_external_s3_resource",
    "snowflake_storage_integration_aws_resource",
  ]
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/snowflake/delphi/external-stages/neo4j-hfr-s3-stage/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

locals {
  snowflake_integration_role_name = "${var.environment}-${var.application_family}-snowflake-integration-role"

  s3_location = "s3://${var.s3_bucket}/${var.s3_prefix}"
}

resource "snowflake_storage_integration_aws" "integration" {
  enabled          = true
  name             = "${var.environment}-${var.application_family}-s3-integration"
  storage_provider = "S3"

  storage_allowed_locations = [local.s3_location]

  storage_aws_role_arn = "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/${local.snowflake_integration_role_name}"
}

resource "snowflake_stage_external_s3" "stage" {
  name                = var.snowflake_stage_name
  url                 = local.s3_location
  database            = var.snowflake_database
  schema              = var.snowflake_schema
  storage_integration = snowflake_storage_integration_aws.integration.name
}

module "stage_access" {
  source = "git@github.com:theorchard/terraform-snowflake.git//modules/roles/stage_access?ref=7.7.7"

  database = snowflake_stage_external_s3.stage.database
  schema   = snowflake_stage_external_s3.stage.schema
  stage    = snowflake_stage_external_s3.stage.name
}