module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "snowflake" {
  account_name      = "delphi"
  organization_name = "sme"
  role              = "PROD_ATLANTIS"
  preview_features_enabled = [
    "snowflake_stage_resource",
    "snowflake_storage_integration_resource",
  ]
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/snowflake/delphi/external-stages/prod-assets-s3-stage/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

data "aws_s3_bucket" "bucket" {
  bucket = "prod-hive-regression-tracking"
}

locals {
  snowflake_integration_role_name = "${var.environment}-${var.application_family}-snowflake-integration-role"
}

resource "snowflake_storage_integration" "integration" {
  name             = "${var.environment}-${var.application_family}-s3-integration"
  storage_provider = "S3"

  storage_allowed_locations = ["s3://${data.aws_s3_bucket.bucket.bucket}/results/"]

  storage_aws_role_arn = "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/${local.snowflake_integration_role_name}"
}

resource "snowflake_stage" "stage" {
  name                = "${var.environment}-${var.application_family}-s3-stage"
  url                 = "s3://${data.aws_s3_bucket.bucket.bucket}/results/"
  database            = "ORCHARD_APP_REPORTING_V2"
  schema              = "PROD_HIVE_MODEL_REPORTING"
  storage_integration = snowflake_storage_integration.integration.name
}

module "assets_stage_access" {
  source = "git@github.com:theorchard/terraform-snowflake.git//modules/roles/stage_access?ref=7.7.4"

  database = snowflake_stage.stage.database
  schema   = snowflake_stage.stage.schema
  stage    = snowflake_stage.stage.name
}

resource "aws_iam_role" "integration_role" {
  name               = local.snowflake_integration_role_name
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

resource "aws_iam_role_policy" "integration_policy" {
  name   = "${var.environment}-${var.application_family}-bucket-snowflake-policy"
  role   = aws_iam_role.integration_role.id
  policy = data.aws_iam_policy_document.inline_policy.json
}

data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"

    principals {
      type = "AWS"
      identifiers = [
        snowflake_storage_integration.integration.storage_aws_iam_user_arn,
        "arn:aws:iam::212740118925:user/91n1-s-vast5230"
      ]
    }

    condition {
      test     = "StringEquals"
      variable = "sts:ExternalId"
      values = [
        snowflake_storage_integration.integration.storage_aws_external_id,
        "DELPHI_SFCRole=2_ZYacTlnhjqXVKPKngZ28/Tr+xWI="
      ]
    }
  }
}

data "aws_iam_policy_document" "inline_policy" {
  statement {
    actions = [
      "s3:GetObject",
      "s3:GetObjectVersion",
    ]
    resources = ["${data.aws_s3_bucket.bucket.arn}/results/*"]
  }

  statement {
    actions = [
      "s3:ListBucket",
      "s3:GetBucketLocation"
    ]
    resources = ["${data.aws_s3_bucket.bucket.arn}"]
  }
}