module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "snowflake" {
  account_name = "delphi"
  role         = "PROD_ATLANTIS"
  preview_features_enabled = [
    "snowflake_storage_integration_resource",
    "snowflake_stage_resource",
  ]
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/snowflake/delphi/external-stages/prod-business-intelligence-s3-stage/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

resource "snowflake_storage_integration" "ds_moments_integration" {
  name             = "${var.environment}-${var.application_family}-s3-integration"
  storage_provider = "S3"

  storage_allowed_locations = ["s3://prod-ds-moments/"]

  storage_aws_role_arn = "arn:aws:iam::313114233826:role/${local.snowflake_integration_role_name}"
}

resource "snowflake_stage" "ds_moments_stage" {
  name                = "${var.environment}-${var.application_family}-s3-stage"
  url                 = "s3://prod-ds-moments/"
  database            = var.stage_snowflake_database
  schema              = var.stage_snowflake_schema
  storage_integration = snowflake_storage_integration.ds_moments_integration.name
}

resource "snowflake_grant_privileges_to_account_role" "ds_moments_stage_grant" {
  for_each = toset([
    "INTELLIGENCE_DB_DBT_PROD_PROJECT_MOMENTS_SCHEMA_READWRITE",
    "INTELLIGENCE_DB_READ_WRITE",
    var.stage_snowflake_role,
  ])

  account_role_name = each.value

  on_schema_object {
    object_type = "STAGE"
    object_name = join(".", [
      snowflake_stage.ds_moments_stage.database,
      snowflake_stage.ds_moments_stage.schema,
      snowflake_stage.ds_moments_stage.name,
    ])
  }

  privileges = ["USAGE"]
}