module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "snowflake" {
  account_name      = "delphi"
  organization_name = "sme"
  role              = "PROD_ATLANTIS"
  preview_features_enabled = [
    "snowflake_stage_resource",
    "snowflake_storage_integration_resource",
  ]
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/snowflake/delphi/external-stages/prod-business-solutions-automations-s3-stage/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

resource "snowflake_storage_integration" "business_solutions_integration" {
  name             = "${var.environment}-${var.application_family}-s3-integration"
  storage_provider = "S3"

  storage_allowed_locations = ["s3://prod-sf-query-results/"]

  storage_aws_role_arn = "arn:aws:iam::009424872958:role/${var.environment}-${var.application_family}-snowflake-integration-role"
}

resource "snowflake_stage" "business_solutions_stage" {
  name                = "${var.environment}-${var.application_family}-s3-stage"
  url                 = "s3://prod-sf-query-results/"
  database            = var.stage_snowflake_database
  schema              = var.stage_snowflake_schema
  storage_integration = snowflake_storage_integration.business_solutions_integration.name
}

module "business_solutions_stage_access" {
  source = "git@github.com:theorchard/terraform-snowflake.git//modules/roles/stage_access?ref=7.1.0"

  database = snowflake_stage.business_solutions_stage.database
  schema   = snowflake_stage.business_solutions_stage.schema
  stage    = snowflake_stage.business_solutions_stage.name
}