module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name = "fansifter"
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "snowflake" {
  account_name      = "delphi"
  organization_name = "sme"
  role              = "PROD_ATLANTIS"
  preview_features_enabled = [
    "snowflake_stage_resource",
    "snowflake_storage_integration_resource",
  ]
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/snowflake/delphi/external-stages/qa-automated-emails-sender/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

resource "snowflake_storage_integration" "fan_response_s3" {
  name             = "${var.environment}-${var.service_name}-s3-export-integration"
  storage_provider = "S3"
  storage_allowed_locations = [
    "s3://${local.bucket_name}/"
  ]
  storage_aws_role_arn = "arn:aws:iam::285943604611:role/${local.iam_role_name}"
}

resource "snowflake_stage" "fan_response_s3_export" {
  name                = "FAN_RESPONSE_S3_EXPORT"
  url                 = "s3://${local.bucket_name}/${local.fan_response_s3_dir}"
  database            = var.snowflake_database
  schema              = var.snowflake_schema
  storage_integration = snowflake_storage_integration.fan_response_s3.name
  directory           = "ENABLE = true"
}

module "fan_response_s3_export_stage_access" {
  source = "git@github.com:theorchard/terraform-snowflake.git//modules/roles/stage_access?ref=7.3.1"

  database = snowflake_stage.fan_response_s3_export.database
  schema   = snowflake_stage.fan_response_s3_export.schema
  stage    = snowflake_stage.fan_response_s3_export.name
}