locals {
  snowflake_integration_role_name = "prod-orcd-ftp-qqmedia-snowflake-integration-role"
}

data "aws_s3_bucket" "bucket" {
  bucket = "prod-orcd-ftp"
}

resource "snowflake_storage_integration_aws" "prod_orcd_ftp_qqmedia_s3_integration" {
  enabled                   = true
  name                      = "PROD_ORCD_FTP_QQMEDIA_S3_INTEGRATION"
  storage_provider          = "S3"
  storage_allowed_locations = ["s3://${data.aws_s3_bucket.bucket.bucket}/ftp/QQMedia/"]
  storage_aws_role_arn      = "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/${local.snowflake_integration_role_name}"
}

data "aws_iam_policy_document" "prod_orcd_ftp_qqmedia_s3_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"

    principals {
      type = "AWS"
      identifiers = [
        snowflake_storage_integration_aws.prod_orcd_ftp_qqmedia_s3_integration.describe_output[0].iam_user_arn,
      ]
    }

    condition {
      test     = "StringEquals"
      variable = "sts:ExternalId"
      values = [
        snowflake_storage_integration_aws.prod_orcd_ftp_qqmedia_s3_integration.describe_output[0].external_id,
      ]
    }
  }
}

data "aws_iam_policy_document" "prod_orcd_ftp_qqmedia_s3_inline_policy" {
  statement {
    actions = [
      "s3:GetObject",
      "s3:GetObjectVersion",
    ]
    resources = ["${data.aws_s3_bucket.bucket.arn}/ftp/QQMedia/*"]
  }

  statement {
    actions = [
      "s3:ListBucket",
      "s3:GetBucketLocation"
    ]
    resources = ["${data.aws_s3_bucket.bucket.arn}"]
  }
}

resource "aws_iam_role" "prod_orcd_ftp_qqmedia_s3_integration_role" {
  name               = local.snowflake_integration_role_name
  assume_role_policy = data.aws_iam_policy_document.prod_orcd_ftp_qqmedia_s3_assume_role_policy.json
}

resource "aws_iam_role_policy" "prod_orcd_ftp_qqmedia_s3_integration_policy" {
  name   = "prod_orcd_ftp_qqmedia-bucket-snowflake-policy"
  role   = aws_iam_role.prod_orcd_ftp_qqmedia_s3_integration_role.id
  policy = data.aws_iam_policy_document.prod_orcd_ftp_qqmedia_s3_inline_policy.json
}