module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/statementdb/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

# KMS key for EBS. The EBS volume no longer exists since it was migrated to the accounting-prod account,
# but keep the KMS key since we still have a final snapshot of the volume encrypted with it.
resource "aws_kms_key" "kms_key" {
  description             = "${var.environment}-${var.service_name}"
  enable_key_rotation     = true
  deletion_window_in_days = 30

  tags = {
    environment        = var.environment
    service_name       = var.service_name
    application_family = var.application_family
    map-migrated       = var.map_migrated_tag
    terraformed        = true
  }
}


resource "aws_kms_alias" "kms_alias" {
  name          = "alias/${var.environment}-${var.service_name}"
  target_key_id = aws_kms_key.kms_key.key_id
}

data "aws_s3_bucket" "upload_bucket" {
  bucket = "${var.environment}-royalties-sales-files"
}

module "s3_read_write_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/s3/buckets_with_prefixes?ref=0.3.0"

  buckets = [
    {
      bucket = data.aws_s3_bucket.upload_bucket.id,
      prefixes = ["statement-db-export/"]
    },
  ]
  action_types = ["read", "write"]
}

resource "aws_iam_policy" "s3_read_write_policy" {
  name   = "S3-${var.environment}-${var.service_name}-${data.aws_s3_bucket.upload_bucket.id}-RW"
  policy = module.s3_read_write_policy.policy.json
}

data "aws_iam_policy_document" "statementdb_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"
    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::375914681009:role/${var.environment}-${var.service_name}-instance-role",
      ]
    }
  }
}

resource "aws_iam_role" "statementdb_assume_role" {
  name               = "${var.environment}-${var.service_name}-upload-role"
  assume_role_policy = data.aws_iam_policy_document.statementdb_assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "statementdb_assume_role_upload_policy_attachment" {
  role       = aws_iam_role.statementdb_assume_role.name
  policy_arn = aws_iam_policy.s3_read_write_policy.arn
}