module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}


terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/streamlit-call-delete-smeanalyticsdummy-product/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "secrets" {
  source             = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each           = toset(var.secrets_manager_secret_names)
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
  application_family = var.application_family
}

data "aws_secretsmanager_secret" "qa_auth0_secret" {
    name = "qa/snowflake-streamlit-data-apps-delete-product/M2M_AUTH0_CLIENT_CREDENTIALS"
}

data "aws_secretsmanager_secret" "prod_auth0_secret" {
    name = "prod/snowflake-streamlit-data-apps-delete-product/M2M_AUTH0_CLIENT_CREDENTIALS"
}

data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

data "aws_iam_policy_document" "streamlit_call_delete_smeanalyticsdummy_product_secrets_policy" {
  statement {
    effect = "Allow"

    actions = [
      "secretsmanager:GetSecretValue",
    ]

    resources = concat([for s in values(module.secrets) : s.secret_arn],
      [data.aws_secretsmanager_secret.qa_auth0_secret.arn,
      data.aws_secretsmanager_secret.prod_auth0_secret.arn] )
  }
}


resource "aws_iam_policy" "streamlit_call_delete_smeanalyticsdummy_product_policy" {
  name   = "SecretsManager-streamlit-call-delete-smeanalyticsdummy-product-secrets-policy"
  policy = data.aws_iam_policy_document.streamlit_call_delete_smeanalyticsdummy_product_secrets_policy.json
}

resource  "aws_iam_role" "streamlit_call_delete_smeanalyticsdummy_product_role"  {
  name = "${var.environment}-${var.service_name}-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "integration_secret_manager_policy_attachment" {
  role       = aws_iam_role.streamlit_call_delete_smeanalyticsdummy_product_role.id
  policy_arn = aws_iam_policy.streamlit_call_delete_smeanalyticsdummy_product_policy.arn
}