terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/streamlit-deployment/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

module "streamlit_deployment_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.delphi_snowflake_streamlit_deployment_user_secrets_manager)

  application_family = var.application_family
  environment        = var.environment
  secret_name        = each.value
  service_name       = var.service_name
}

module "secrets_manager_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/secretsmanager/secrets_list?ref=0.4.0"

  secrets      = ["${var.environment}/${var.service_name}/PRIVATE_KEY", "${var.environment}/${var.service_name}/PRIVATE_KEY_PASSPHRASE"]
  action_types = ["read"]

  depends_on = [
    module.streamlit_deployment_secrets,
  ]
}

data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

resource "aws_iam_role" "integration_role" {
  name               = "${var.environment}-${var.service_name}-integration-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

resource "aws_iam_policy" "secrets_manager_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-integration-test-policy"
  policy = module.secrets_manager_policy.policy.json
}

resource "aws_iam_role_policy_attachment" "integration_role_policy_attachment" {
  role       = aws_iam_role.integration_role.id
  policy_arn = aws_iam_policy.secrets_manager_policy.arn
}

output "role_output" {
 value = aws_iam_role.integration_role.arn
}