module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/swf-feed-ingestion/amazon_music/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

module "multiple_secrets_with_same_settings" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment        = var.environment
  service_name       = var.secrets_manager_service_name
  secret_name        = each.value
  application_family = var.application_family
}

data "aws_iam_policy" "existing_swf_policies" {
  for_each = toset(local.existing_swf_policy_names)
  name     = each.value
}

data "aws_iam_policy" "execution_role_existing_swf_policies" {
  for_each = toset(local.execution_role_existing_swf_policy_names)
  name     = each.value
}

module "fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.5.0"

  providers = {
    aws.dns = aws
  }

  environment                  = var.environment
  service_name                 = var.service_name
  secrets_manager_service_name = var.secrets_manager_service_name
  non_ecr_image                = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/swf-feed-ingestion:latest"
  application_family           = var.application_family
  aws_region                   = var.aws_region
  additional_tags              = var.additional_tags
  commit_sha                   = "latest"
  container_port               = "8080"
  task_type                    = "worker"
  desired_task_count           = 1
  task_cpu                     = 4096
  task_memory                  = 8192
  task_ephemeral_storage_size  = 200
  maximum_capacity             = 1
  minimum_capacity             = 1
  vpc_id                       = module.vpc_info.vpc_id

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  iam_managed_policy_attachments = [
    for policy in data.aws_iam_policy.existing_swf_policies : policy.arn
  ]
  execution_role_iam_managed_policy_attachments = [
    for policy in data.aws_iam_policy.execution_role_existing_swf_policies : policy.arn
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      DD_LOGS_INJECTION = "true"
    },
    {
      AWS_REGION = var.aws_region
    },
    {
      SWF_DOMAIN = local.swf_domain
    },
    {
      FEED_INGESTION_DATA_BUCKET = var.feed_ingestion_data_bucket
    },
    {
      FEED_INGESTION_DROP_BUCKET = var.feed_ingestion_drop_bucket
    },
    {
      FEED_INGESTION_TABLE = local.feed_ingestion_table
    },
    {
      SNOWFLAKE_USER = var.snowflake_user
    },
    {
      SNOWFLAKE_SCHEMA = var.snowflake_schema
    },
    {
      SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    },
    {
      SNOWFLAKE_ACCOUNT = var.snowflake_account
    },
    {
      SNOWFLAKE_DATABASE = var.snowflake_database
    },
    {
      SNOWFLAKE_ROLE = var.snowflake_role
    },
    {
      FEED_INGESTION_SNS_TOPIC = local.feed_ingestion_sns_topic
    },
    {
      GARCON_FLOW_NAME = var.flow_name
    }
  ]

  secrets = [
    {
      SENTRY_DSN = "${var.environment}/${var.secrets_manager_service_name}/SENTRY_DSN"
    },
    {
      SNOWFLAKE_KEY = "${var.environment}/${var.secrets_manager_service_name}/SNOWFLAKE_KEY"
    },
    {
      SME_AWS_ACCESS_KEY_ID = "${var.environment}/${var.sme_partners_s3_access_secrets_manager_service_name}/SME_AWS_ACCESS_KEY_ID"
    },
    {
      SME_AWS_SECRET_ACCESS_KEY = "${var.environment}/${var.sme_partners_s3_access_secrets_manager_service_name}/SME_AWS_SECRET_ACCESS_KEY"
    },
  ]
}

module "sentry_project" {
  source                       = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"
  service_name                 = var.service_name
  secrets_manager_service_name = var.secrets_manager_service_name
  application_family           = var.application_family
  environment                  = var.environment
  teams                        = [var.environment]
  platform                     = "python"
}

module "fargate_service_dashboard" {
  source                      = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.18.2"
  environment                 = var.environment
  environment_type            = "fargate"
  application_family          = var.application_family
  service_name                = var.service_name
  service_4xx_monitor_enabled = false
  service_5xx_monitor_enabled = false
  service_cpu_monitor_enabled = false

  notification_endpoints            = var.notification_endpoint
  escalation_notification_endpoints = var.escalation_notification_endpoints
}

module "sqs_data_availability_queue" {
  source = "git@github.com:theorchard/terraform-sqs.git?ref=2.5.0"
  environment                          = var.environment
  application_family                   = var.application_family
  queue_name                           = var.sqs_data_availability_queue_name
  sqs_encryption_type                  = "sse-sqs"
  sqs_delay_seconds                    = 0
  sqs_max_message_size                 = 1048576
  # 4 days
  sqs_message_retention_seconds        = 86400 * 4
  sqs_visibility_timeout_seconds       = 600
  sqs_deadletter_enabled               = true
  deadletter_max_message_size          = 1048576
  # 14 days
  deadletter_message_retention_seconds = 1209600
}

data "aws_iam_policy_document" "sqs_sns_policy" {
  statement {
    sid       = "Allow_Amazon_Music_SNS_topic_to_Send_Message"
    effect    = "Allow"
    actions   = ["sqs:SendMessage"]
    resources = [module.sqs_data_availability_queue.queue_arn]

    principals {
      type        = "Service"
      identifiers = ["sns.amazonaws.com"]
    }

    condition {
      test     = "ArnLike"
      variable = "aws:SourceArn"
      values   = ["arn:aws:sns:us-east-1:767398096717:TableUpdateTopic"]
    }
  }
}

resource "aws_sqs_queue_policy" "sqs_data_availability_policy" {
  policy    = data.aws_iam_policy_document.sqs_sns_policy.json
  queue_url = module.sqs_data_availability_queue.queue_url
}