module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/swf-feed-ingestion/chartmetric-socials-backfill/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.secrets_manager_service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

data "aws_iam_policy" "existing_swf_policies" {
  for_each = toset(local.existing_swf_policy_names)
  name     = each.value
}

module "fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.7.0"

  providers = {
    aws.dns = aws
  }

  environment                  = var.environment
  service_name                 = var.service_name
  application_family           = var.application_family
  aws_region                   = var.aws_region
  secrets_manager_service_name = var.secrets_manager_service_name
  commit_sha                   = "latest"
  service_platform_version     = "1.4.0"
  container_port               = "8080"
  task_type                    = "worker"
  desired_task_count           = 1
  task_cpu                     = 4096
  task_memory                  = 8192
  maximum_capacity             = 1
  minimum_capacity             = 1
  vpc_id                       = module.vpc_info.vpc_id

  non_ecr_image = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/swf-feed-ingestion:latest"

  iam_managed_policy_attachments = [
    for policy in data.aws_iam_policy.existing_swf_policies : policy.arn
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      DD_LOGS_INJECTION = "true"
    },
    {
      AWS_REGION = var.aws_region
    },
    {
      FEED_INGESTION_TABLE = local.feed_ingestion_table
    },
    {
      SWF_DOMAIN = local.swf_domain
    },
    {
      SNOWFLAKE_ACCOUNT = var.snowflake_account
    },
    {
      SNOWFLAKE_DATABASE = var.snowflake_database
    },
    {
      SNOWFLAKE_SCHEMA = var.snowflake_schema
    },
    {
      SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    },
    {
      SNOWFLAKE_ROLE = var.snowflake_role
    },
    {
      SNOWFLAKE_USER = var.snowflake_user
    },
    {
      NEO4J_URL = var.neo4j_url
    },
    {
      GARCON_FLOW_NAME = var.flow_name
    }
  ]
  secrets = [
    {
      SENTRY_DSN = "${var.environment}/${var.secrets_manager_service_name}/SENTRY_DSN"
    },
    {
      NEO4J_USER = "${var.environment}/${var.secrets_manager_service_name}/NEO4J_USER"
    },
    {
      NEO4J_PASSWORD = "${var.environment}/${var.secrets_manager_service_name}/NEO4J_PASSWORD"
    },
    {
      SNOWFLAKE_KEY = "${var.environment}/${var.secrets_manager_service_name}/SNOWFLAKE_KEY"
    },
  ]
}

module "sentry_project" {
  source                       = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"
  service_name                 = var.service_name
  application_family           = var.application_family
  environment                  = var.environment
  teams                        = [var.environment]
  platform                     = "python"
  secrets_manager_service_name = var.secrets_manager_service_name
}

module "fargate_service_dashboard" {
  source                         = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.4"
  environment                    = var.environment
  environment_type               = "fargate"
  service_name                   = var.service_name
  application_family             = var.application_family
  service_4xx_monitor_enabled    = false
  service_5xx_monitor_enabled    = false
  healthy_tasks_monitor_silenced = true

  notification_endpoints            = "@slack-data-alerts"
  escalation_notification_endpoints = "@slack-data-alarm"
}