# Allow service to assume role for cross-account Kafka access
data "aws_iam_policy_document" "consumer_assume_role_policy" {
  statement {
    actions = [
      "sts:AssumeRole",
    ]
    resources = ["arn:aws:iam::019963779799:role/ProdOrchardAccess"]
  }
}

resource "aws_iam_policy" "consumer_assume_role_policy" {
  name   = "${var.environment}-${var.service_name}-sts-assume-role-policy"
  policy = data.aws_iam_policy_document.consumer_assume_role_policy.json
}

data "aws_secretsmanager_secret" "producer_sentry_dsn" {
  name = "${var.environment}/switchboard-producer/SENTRY_DSN"
}

data "aws_secretsmanager_secret_version" "producer_sentry_dsn" {
  secret_id = data.aws_secretsmanager_secret.producer_sentry_dsn.id
}

# Allow service to read shared graphql-switchboard secret
data "aws_iam_policy_document" "consumer_secrets_manager_policy" {
  statement {
    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds",
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/graphql-switchboard/CONSUMER_SECRET",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/graphql-switchboard/CONSUMER_SECRET*",
    ]
  }

  statement {
    actions = [
      "secretsmanager:GetRandomPassword",
    ]

    resources = [
      "*",
    ]
  }
}

resource "aws_iam_policy" "consumer_secrets_manager_policy" {
  name   = "${var.environment}-${var.service_name}-shared-secrets-manager-policy"
  policy = data.aws_iam_policy_document.consumer_secrets_manager_policy.json
}

data "aws_secretsmanager_secret" "graphql_consumer_secret" {
  name = "${var.environment}/graphql-switchboard/CONSUMER_SECRET"
}

resource "aws_iam_policy" "kinesis_readonly_policy" {
  name   = "${var.environment}-${var.service_name}-kinesis-RO-policy"
  policy = data.aws_iam_policy_document.kinesis_readonly_policy.json
}

data "aws_iam_policy_document" "kinesis_readonly_policy" {
  statement {
    actions = [
      "kinesis:ListShards",
      "kinesis:ListStreams",
      "kinesis:GetShardIterator",
      "kinesis:GetRecords",
      "kinesis:DescribeStream",
      "kinesis:DescribeStreamConsumer",
      "kinesis:DescribeStreamSummary",
    ]

    resources = [
      module.switchboard_kinesis_stream.kinesis_stream_arn,
    ]
  }
}

module "switchboard_producer_owsrequest_policy" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = "switchboard-producer"
}

module "lambda_kinesis_to_kafka" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=4.1.0"

  environment        = var.environment
  application_family = var.application_family
  lambda_name        = "lambda-switchboard-producer-kinesis-to-kafka"

  lambda_description          = "Notifies Kafka about metadata changes"
  lambda_function_timeout     = "300"
  lambda_function_memory_size = "512"
  use_container_image         = true
  vpc_enabled                 = true
  vpc_id                      = data.aws_vpc.vpc.id
  vpc_subnet_ids              = data.aws_subnets.private.ids

  datadog_enabled          = true
  datadog_advanced_enabled = true

  event_source_mapping_enabled           = true
  event_source_mapping_resource_type     = "kinesis"
  event_source_mapping_stream_name       = module.switchboard_kinesis_stream.kinesis_stream_name
  event_source_mapping_batch_size        = "10"
  event_source_mapping_starting_position = "LATEST"

  lambda_function_environment_variables = {
    Environment          = var.environment
    LOGGER_DSN           = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    SENTRY_DSN           = data.aws_secretsmanager_secret_version.producer_sentry_dsn.secret_string
    KAFKA_CLUSTER_ARN    = "arn:aws:kafka:us-east-1:019963779799:cluster/sme-switchboard-msk-prod/277f8d91-ecd8-4662-b638-d9d2e3819279-6"
    SWITCHBOARD_ROLE_ARN = "arn:aws:iam::019963779799:role/ProdOrchardAccess"
    GRAPHQL_URL          = "https://graphql-switchboard.theorchard.io/graphql"
    GRAPHQL_SECRET_NAME  = data.aws_secretsmanager_secret.graphql_consumer_secret.arn
  }

  iam_managed_policy_attachments = [
    aws_iam_policy.consumer_assume_role_policy.arn,
    aws_iam_policy.kinesis_readonly_policy.arn,
    module.switchboard_producer_owsrequest_policy.policy_arn_output,
    aws_iam_policy.consumer_secrets_manager_policy.arn,
  ]

}

module "lambda_kinesis_to_kafka_datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.18.1"

  environment                       = var.environment
  service_name                      = "kinesis-to-kafka"
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.escalation_notification_endpoints
}

module "lambda_kinesis_to_kafka_sentry" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  service_name       = "kinesis-to-kafka"
  environment        = var.environment
  platform           = "python"
  application_family = var.application_family
}