provider "aws" {
  region = var.aws_region
}

# S3 backend
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/terraform-state-file-fixer/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "secrets" {
  for_each = toset(var.secrets_manager_secret_names)
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.0.6"

  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
  application_family = var.application_family
}

data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

resource "aws_iam_role" "main" {
  name               = "${var.environment}-${var.service_name}-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json

  tags = {
    environment        = var.environment
    service_name       = var.service_name
    application_family = var.application_family
    terraformed        = true
  }
}

data "aws_s3_bucket" "terraform_state_bucket" {
  bucket = "orcd-terraform-state"
}

module "s3_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/s3/buckets_with_prefixes?ref=0.2.0"

  buckets = [{
    bucket = data.aws_s3_bucket.terraform_state_bucket.bucket
  }]
  action_types = ["read", "write"]
}

module "secrets_manager_policy" {
  depends_on = [module.secrets]
  source     = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/secretsmanager/secrets_list?ref=0.2.0"

  secrets      = [for secret in module.secrets : secret.secret_name]
  action_types = ["read"]
}

resource "aws_iam_role_policy" "s3_policy" {
  name   = "S3-${data.aws_s3_bucket.terraform_state_bucket.bucket}-RW"
  policy = module.s3_policy.policy.json
  role   = aws_iam_role.main.id
}

resource "aws_iam_role_policy" "secrets_manager_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-RO"
  policy = module.secrets_manager_policy.policy.json
  role   = aws_iam_role.main.id
}