provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/vector/audit/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_iam_policy" "audit_bucket_ro" {
  name = "S3-${module.vector_audit_s3_bucket.s3_bucket_name_output}-RO"
}

module "vector_audit_s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.13.0"

  bucket_name         = "vector-audit"
  env                 = var.environment
  application_family  = var.application_family
  s3_read_only_policy = true

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  lifecycle_rules_options_current_version_transition = [
    {
      prefix        = ""
      enabled       = true
      days          = 0
      storage_class = "INTELLIGENT_TIERING"
    },
    {
      prefix        = "metadata"
      enabled       = true
      days          = 180
      storage_class = "GLACIER"
    }
  ]
}

resource "aws_iam_group" "audit_bucket_read_group" {
  name = "${module.vector_audit_s3_bucket.s3_bucket_name_output}-read"
}

resource "aws_iam_group_policy_attachment" "audit_bucket_read_policy_attachment" {
  group      = aws_iam_group.audit_bucket_read_group.name
  policy_arn = data.aws_iam_policy.audit_bucket_ro.arn
}

resource "aws_iam_group_membership" "audit_bucket_read_group_membership" {
  name = "${aws_iam_group.audit_bucket_read_group.name}-membership"

  users = [
    "astephenson",
    "gaguirre",
    "mdadhania",
  ]

  group = aws_iam_group.audit_bucket_read_group.name
}

# Data resource for restore policy to the S3 bucket.
data "aws_iam_policy_document" "s3_audit_bucket_restore_policy" {
  statement {
    actions = [
      "s3:RestoreObject",
    ]

    resources = [
      "${module.vector_audit_s3_bucket.s3_bucket_arn_output}/*",
    ]
  }

  statement {
    actions = [
      "s3:ListBucket",
    ]

    resources = [
      module.vector_audit_s3_bucket.s3_bucket_arn_output,
    ]
  }

  statement {
    actions = [
      "s3:GetBucketLocation",
      "s3:ListAllMyBuckets",
    ]

    resources = [
      "*",
    ]
  }
}

# Creates policy for object restore access to the S3 bucket.
resource "aws_iam_policy" "s3_audit_bucket_restore_only_policy" {
  name   = "${module.vector_audit_s3_bucket.s3_bucket_name_output}-restore-from-glacier"
  policy = data.aws_iam_policy_document.s3_audit_bucket_restore_policy.json
}

# IAM group for restoring objects from Glacier.
resource "aws_iam_group" "s3_audit_bucket_restore_group" {
  name = "${module.vector_audit_s3_bucket.s3_bucket_name_output}-restore-from-glacier"
}

resource "aws_iam_group_membership" "s3_audit_bucket_read_group_membership" {
  name = "${aws_iam_group.s3_audit_bucket_restore_group.name}-membership"

  users = [
    "astephenson",
  ]

  group = aws_iam_group.s3_audit_bucket_restore_group.name
}

resource "aws_iam_group_policy_attachment" "s3_audit_bucket_restore_policy_attachment" {
  group      = aws_iam_group.s3_audit_bucket_restore_group.name
  policy_arn = aws_iam_policy.s3_audit_bucket_restore_only_policy.arn
}