module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# S3 backend
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/vector/temp-blurb-delivery/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

resource "aws_iam_user" "vector_temp_blurb_delivery_bucket_user" {
  name = "${var.environment}-${var.service_name}"

  tags = {
    role = "service-user"
  }
}

resource "aws_iam_user" "temp_blurb_delivery_third_party_user" {
  name = "${var.environment}-${var.service_name}-download"

  tags = {
    terraformed = true
    name        = "${var.environment}-${var.service_name}-download"
    email       = "jt@blurb.fm"
    role        = "business"
    company     = "Blurb"
    manager     = "Joseph Barcella"
  }
}

module "temp_blurb_delivery_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.12.1"

  env                 = var.environment
  bucket_name         = var.service_name
  application_family  = var.application_family
  s3_read_only_policy = false

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  lifecycle_rules_options_noncurrent_version_expiration = [
    {
      prefix        = ""
      enabled       = true
      days          = 30
    }
  ]

  lifecycle_rules_options_current_version_expiration = [
    {
      prefix        = ""
      enabled       = true
      days          = 90
    }
  ]
}

module "temp_blurb_delivery_bucket_read_write_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/s3/buckets_with_prefixes?ref=0.3.0"

  buckets = [{
    bucket = module.temp_blurb_delivery_bucket.s3_bucket_name_output
  }]
  action_types          = ["write"]
  enable_global_actions = false
}

resource "aws_iam_user_policy" "s3_read_write_policy" {
  name   = "S3-${module.temp_blurb_delivery_bucket.s3_bucket_name_output}-RW"
  policy = module.temp_blurb_delivery_bucket_read_write_policy.policy.json
  user   = aws_iam_user.vector_temp_blurb_delivery_bucket_user.name
}

module "temp_blurb_delivery_bucket_read_only_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/s3/buckets_with_prefixes?ref=0.3.0"

  buckets = [{
    bucket = module.temp_blurb_delivery_bucket.s3_bucket_name_output
  }]
  action_types          = ["read"]
  enable_global_actions = false
}

resource "aws_iam_policy" "s3_read_only_policy" {
  name   = "S3-${module.temp_blurb_delivery_bucket.s3_bucket_name_output}-RO"
  policy = module.temp_blurb_delivery_bucket_read_only_policy.policy.json
}

resource "aws_iam_user_policy_attachment" "s3_third_party_user_read_only_policy_attachment" {
  policy_arn = aws_iam_policy.s3_read_only_policy.arn
  user       = aws_iam_user.temp_blurb_delivery_third_party_user.name
}