module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
provider "aws" {
  alias  = "aws_us_west_2"
  region = "us-west-2"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/workstation/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_com" {
  domain   = "*.theorchard.com"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "theorchard_io_zone" {
  name = "theorchard.io"
}


# TODO: add cloudflare support
# data "cloudflare_ip_ranges" "cloudflare" {}

# data "cloudflare_zone" "cloudflare_domain" {
#   name = var.domain_name
# }

data "aws_ec2_managed_prefix_list" "cloudfront" {
  name = "com.amazonaws.global.cloudfront.origin-facing"
}

data "aws_iam_user" "user" {
  user_name = "${var.environment}-${var.service_name}-user"
}

data "aws_iam_policy" "ows_machine_to_machine_policy" {
  name = "SecretsManager-${var.environment}-ows-machine-to-machine-policy"
}

data "aws_s3_bucket" "logging_bucket" {
  bucket = "aws-waf-logs-prod-tf-orcd-bucket"
}

data "aws_elasticache_replication_group" "split_synchronizer_redis_cache" {
  replication_group_id = "${var.environment}-split-synchronizer"
}

data "aws_secretsmanager_secret" "splitio_api_key" {
  name = "${var.environment}/split/API_KEY"
}

module "workstation_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.5.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                              = var.environment
  service_name                             = var.service_name
  aws_region                               = var.aws_region
  application_family                       = var.application_family
  service_platform_version                 = "1.4.0"
  deployment_minimum_healthy_percent       = "100"
  desired_task_count                       = 6
  minimum_capacity                         = 6
  maximum_capacity                         = 12
  task_cpu                                 = 4096
  task_memory                              = 12288
  container_port                           = 8080
  health_check_grace_period_seconds        = 300
  container_start_period_seconds           = 300
  target_deregistration_delay              = 300
  health_check_path                        = "/healthchk.php"
  load_balancer_idle_timeout               = "100"
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  load_balancer_is_internal                = "false"
  vpc_id                                   = module.vpc_info.vpc_id
  fargate_service_subnets                  = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets                    = module.vpc_info.default_public_subnet_ids
  custom_waf_arn                           = module.custom_waf.waf_blocking_arn_output
  # ACM certificate id for theorchard.com
  https_listener_certificate_id = split("/", data.aws_acm_certificate.theorchard_com.arn)[1]
  iam_managed_policy_attachments = [
    aws_iam_policy.workstation_kms_policy.arn,
    aws_iam_policy.s3_configs_read_only_policy.arn,
    module.efs_volume.efs_iam_policy_arn_output,
  ]
  # TODO: change to use Cloudflare data source
  # Cloudflare, AVL, and NY egress IPv4 address blocks
  prod_https_listener_allow_cidr_blocks = [
    "103.21.244.0/22",
    "103.22.200.0/22",
    "103.31.4.0/22",
    "104.16.0.0/12",
    "104.24.0.0/14",
    "108.162.192.0/18",
    "131.0.72.0/22",
    "141.101.64.0/18",
    "162.158.0.0/15",
    "172.64.0.0/13",
    "173.245.48.0/20",
    "188.114.96.0/20",
    "190.93.240.0/20",
    "197.234.240.0/22",
    "198.41.128.0/17",
    "207.237.185.2/32",
    "208.91.130.130/32",
  ]
  docker_volumes = [
    {
      name            = "${var.environment}-${var.service_name}"
      file_system_id  = module.efs_volume.efs_file_system_id_output
      access_point_id = module.efs_volume.efs_access_point_id_output
    }
  ]

  docker_volume_mount_points = [
    {
      source_volume  = "${var.environment}-${var.service_name}"
      container_path = var.efs_volume_container_path
    }
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      APPLICATION_ENV = "production"
    },
    {
      DD_SERVICE_NAME = "${var.environment}-${var.service_name}"
    },
    {
      DD_TRACE_ANALYTICS_ENABLED = "true"
    },
    {
      DD_TRACE_APP_NAME = "${var.environment}-${var.service_name}"
    },
    {
      DD_TRACE_GLOBAL_TAGS = "env:${var.environment}-${var.service_name}"
    },
    {
      PHP_DISPLAY_ERRORS = "false"
    },
    {
      PHP_SESSION_COOKIE_SECURE = "1"
    },
    {
      PHP_SESSION_COOKIE_HTTPONLY = "1"
    },
    {
      PHP_SESSION_SAVE_HANDLER = "memcached"
    },
    {
      PHP_SESSION_SAVE_PATH = "${var.environment}-oa-workstation-session-cache-memcached.theorchard.io:11211"
    },
    {
      S3_CONFIG_LOCATION = "${var.config_s3_bucket}/${var.service_name}/${var.environment}"
    },
    {
      EFS_VOLUME_CONTAINER_PATH = var.efs_volume_container_path
    },
    {
      BULKUPLOAD_DOMAIN = var.bulkupload_domain_name
    },
    {
      SENTRY_DSN = "https://a5813cceb99d43e5bffab5662a3a402f@o22178.ingest.us.sentry.io/67603"
    },
    {
      API_BASE_URL = "https://login.distroauth.com"
    },
    {
      AUTH0_DOMAIN = "login.distroauth.com"
    },
    {
      AUDIENCE = "https://workstation.theorchard.com/api"
    },
    {
      CONNECTION = "art-relations"
    },
    {
      WS_COOKIE_EXPIRY = "604800"
    },
    {
      SPLITIO_REDIS_HOST = data.aws_elasticache_replication_group.split_synchronizer_redis_cache.primary_endpoint_address
    },
    {
      SPLITIO_REDIS_PORT = data.aws_elasticache_replication_group.split_synchronizer_redis_cache.port
    },
  ]
  secrets = [
    {
      AWAL_ORG_ID = "${var.environment}/${var.service_name}/AWAL_ORG_ID"
    },
    {
      WS_CLIENT_ID = "${var.environment}/${var.service_name}/WS_CLIENT_ID"
    },
    {
      WS_CLIENT_SECRET = "${var.environment}/${var.service_name}/WS_CLIENT_SECRET"
    },
    {
      WS_COOKIE_SECRET = "${var.environment}/${var.service_name}/WS_COOKIE_SECRET"
    },
    {
      SPLITIO_API_KEY = "${var.environment}/split/API_KEY"
    },
  ]
}

module "workstation_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.6.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = "security-tools"
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
}

# Because we are using a managed prefix list, we need a discrete resource
resource "aws_security_group_rule" "allow_access_to_lb_from_cloudfront" {
  description       = "allow_https_access_from_cloudfront"
  type              = "ingress"
  security_group_id = module.workstation_fargate_environment.fargate_load_balancer_security_group_id
  from_port         = 443
  to_port           = 443
  protocol          = "tcp"
  prefix_list_ids   = [data.aws_ec2_managed_prefix_list.cloudfront.id]
}

module "m2m_secrets" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//modules/auth0m2m?ref=1.6.1"

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family
}

# TODO: add cloudflare support
# resource "cloudflare_record" "workstation_lb_cname_record" {
#   zone_id = data.cloudflare_zone.cloudflare_domain.id
#   name    = "${var.service_name}-lb"
#   value   = module.workstation_fargate_environment.fargate_load_balancer_dns_name
#   type    = "CNAME"
#   proxied = true
# }

resource "aws_iam_user_policy_attachment" "user_policy_attachment" {
  user       = data.aws_iam_user.user.user_name
  policy_arn = data.aws_iam_policy.ows_machine_to_machine_policy.arn
}

module "workstation_fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.14.3"

  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = var.application_family
  notification_endpoints            = "@slack-devops @oncall-devops"
  escalation_notification_endpoints = "@slack-devops @oncall-devops"
  critical_number_5xx               = 599
  critical_recovery_number_5xx      = 550
  warning_number_5xx                = 499
  warning_recovery_number_5xx       = 450
  # /grasssession returns 403 as a feature on token timeout, so disable this monitor
  service_4xx_monitor_enabled = false
}