module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/wowza/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_com" {
  domain   = "*.theorchard.com"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

data "cloudflare_ip_ranges" "cloudflare" {}

module "fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.1"

  providers = {
    aws.dns = aws.networking
  }

  environment                     = var.environment
  service_name                    = var.service_name
  application_family              = var.application_family
  secrets_manager_service_name    = var.service_name
  non_ecr_image                   = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/wowza:latest"
  aws_region                      = var.aws_region
  commit_sha                      = "latest"
  container_port                  = "1935"
  task_type                       = "web_service"
  health_check_path               = var.health_check_path
  https_listener_enabled          = true
  desired_task_count              = 2
  task_cpu                        = 2048
  task_memory                     = 4096
  task_ephemeral_storage_size     = 60
  minimum_capacity                = 2
  maximum_capacity                = 4
  vpc_id                          = module.vpc_info.vpc_id
  https_listener_certificate_id   = split("/", data.aws_acm_certificate.theorchard_com.arn)[1]
  route53_zone_id                 = data.aws_route53_zone.route53_zone.zone_id
  target_group_stickiness_enabled = true
  splitio_enabled                 = false
  ows_machine_to_machine_enabled  = false
  load_balancer_is_internal       = false

  prod_https_listener_allow_cidr_blocks = data.cloudflare_ip_ranges.cloudflare.ipv4_cidr_blocks

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_public_subnet_ids

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      SERVICE_NAME = var.service_name
    },
  ]
  secrets = [
    {
      AWS_ACCESS_KEY_ID = "${var.environment}/${var.service_name}/AWS_ACCESS_KEY_ID"
    },
    {
      AWS_SECRET_ACCESS_KEY = "${var.environment}/${var.service_name}/AWS_SECRET_ACCESS_KEY"
    },
    {
      CUPERTINO_ENCRYPTION_SHARED_SECRET = "${var.environment}/${var.service_name}/CUPERTINO_ENCRYPTION_SHARED_SECRET"
    },
    {
      WSE_LIC = "${var.environment}/${var.service_name}/WSE_LIC"
    },
    {
      WSE_MGR_PASS = "${var.environment}/${var.service_name}/WSE_MGR_PASS"
    },
    {
      WSE_MGR_USER = "${var.environment}/${var.service_name}/WSE_MGR_USER"
    },
  ]
}

module "fargate_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.4"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = var.application_family
  notification_endpoints            = "@slack-devops-internal-alerts"
  escalation_notification_endpoints = "@slack-devops-internal-alerts"
}

module "wowza_secrets_manager" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.wowza_secrets)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
}

# Create listener rules for allowed paths - each path gets a rule that forwards to target group
resource "aws_lb_listener_rule" "health_check" {
  listener_arn = module.fargate_environment.fargate_load_balancer_https_listener_arn
  priority     = 1

  action {
    type             = "forward"
    target_group_arn = module.fargate_environment.fargate_target_group_arn
  }

  condition {
    path_pattern {
      values = [var.health_check_path]
    }
  }
}

resource "aws_lb_listener_rule" "allowed_paths" {
  for_each = toset(var.allowed_app_paths)

  listener_arn = module.fargate_environment.fargate_load_balancer_https_listener_arn
  priority     = 2 + index(var.allowed_app_paths, each.value)

  action {
    type             = "forward"
    target_group_arn = module.fargate_environment.fargate_target_group_arn
  }

  condition {
    path_pattern {
      values = ["/${each.value}/*"]
    }
  }
}

# Default rule to block all other paths with 403
resource "aws_lb_listener_rule" "block_all_other_paths" {
  listener_arn = module.fargate_environment.fargate_load_balancer_https_listener_arn
  priority     = 999

  action {
    type = "fixed-response"

    fixed_response {
      content_type = "text/plain"
      message_body = "Forbidden"
      status_code  = "403"
    }
  }

  condition {
    path_pattern {
      values = ["/*"]
    }
  }
}