provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/abacus-legacy-bridge/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

# Bucket for storing abacus output files that are a result of the abacus calculation
module "s3_abacus_legacy_bridge_bucket" {
  source              = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=2.5.1"
  env                 = var.environment
  bucket_name         = var.bucket_name
  kms_key_enabled     = true
  kms_key_name        = "abacus_legacy_bridge"
  s3_read_only_policy = true
  application_family  = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm     = "aws:kms"
    kms_master_key_id = module.s3_abacus_legacy_bridge_bucket.s3_kms_encryption_key_id_output
  }
}

# IAM kms policy document for abacus-legacy-bridge s3 bucket
data "aws_iam_policy_document" "abacus_legacy_bridge_kms_key_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "kms:Encrypt",
      "kms:Decrypt",
      "kms:ReEncrypt*",
      "kms:GenerateDataKey*",
      "kms:DescribeKey"
    ]
    resources = [
      module.s3_abacus_legacy_bridge_bucket.s3_kms_encryption_key_arn_output
    ]
  }
}

resource "aws_iam_policy" "abacus_legacy_bridge_kms_key_policy" {
  name   = "KMS-${var.environment}-${var.service_name}-encrypt-decrypt-policy"
  policy = data.aws_iam_policy_document.abacus_legacy_bridge_kms_key_policy_document.json
}

# Create read/write IAM policy document for abacus-legacy-bridge s3 bucket
data "aws_iam_policy_document" "s3_abacus_legacy_bridge_bucket_s3_read_write_policy" {
  statement {
    actions = [
      "s3:GetBucketLocation",
      "s3:GetObject",
      "s3:GetObject*",
      "s3:ListBucket",
      "s3:PutObject",
      "s3:PutObject*",
      "s3:DeleteObject*",
    ]

    resources = [
      "${module.s3_abacus_legacy_bridge_bucket.s3_bucket_arn_output}/*"
    ]
  }

  statement {
    actions = [
      "s3:ListBucket",
    ]

    resources = [
      module.s3_abacus_legacy_bridge_bucket.s3_bucket_arn_output
    ]
  }

  statement {
    actions = [
      "s3:GetBucketLocation",
      "s3:ListAllMyBuckets"
    ]

    resources = [
      "*"
    ]
  }
}

# Create read/write iam policy for abacus-legacy-bridge s3 bucket
resource "aws_iam_policy" "s3_read_write_policy" {
  name   = "S3-${var.environment}-${var.bucket_name}-read-write-policy"
  policy = data.aws_iam_policy_document.s3_abacus_legacy_bridge_bucket_s3_read_write_policy.json
}

# Create IAM user for snowflake stage
resource "aws_iam_user" "iam_user" {
  name = "${var.environment}-${var.service_name}-user"
  tags = {
    terraformed = true
  }
}

resource "aws_iam_user_policy_attachment" "iam_user_policy_attachment" {
  for_each = toset([
    "arn:aws:iam::437795906767:policy/S3-qa-abacus-legacy-bridge-read-write-policy",
    "arn:aws:iam::437795906767:policy/KMS-qa-abacus-legacy-bridge-encrypt-decrypt-policy",
  ])

  policy_arn = each.value
  user       = aws_iam_user.iam_user.name
}