provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/abacus-sap-payment-files/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

# Bucket for storing SAP payment files.
module "s3_abacus_sap_payment_files_bucket" {
  source              = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.14.1"
  env                 = var.environment
  bucket_name         = var.bucket_name
  kms_key_enabled     = true
  kms_key_name        = "abacus_sap_payment_files"
  application_family  = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm     = "aws:kms"
  }
}

# IAM kms policy document for abacus-sap-payment-files s3 bucket
data "aws_iam_policy_document" "s3_abacus_sap_payment_files_kms_key_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "kms:Encrypt",
      "kms:Decrypt",
      "kms:ReEncrypt*",
      "kms:GenerateDataKey*",
      "kms:DescribeKey"
    ]
    resources = [
      module.s3_abacus_sap_payment_files_bucket.s3_kms_encryption_key_arn_output
    ]
  }
}

resource "aws_iam_policy" "s3_abacus_sap_payment_files_kms_key_policy" {
  name   = "KMS-${var.environment}-${var.service_name}-encrypt-decrypt-policy"
  policy = data.aws_iam_policy_document.s3_abacus_sap_payment_files_kms_key_policy_document.json
}

# Create read/write IAM policy document for abacus-sap-payment-files s3 bucket
data "aws_iam_policy_document" "s3_abacus_sap_payment_files_bucket_s3_read_write_policy" {
  statement {
    actions = [
      "s3:GetBucketLocation",
      "s3:GetObject*",
      "s3:ListBucket",
      "s3:PutObject*",
      "s3:DeleteObject*",
    ]

    resources = [
      "${module.s3_abacus_sap_payment_files_bucket.s3_bucket_arn_output}/*"
    ]
  }

  statement {
    actions = [
      "s3:ListBucket",
    ]

    resources = [
      module.s3_abacus_sap_payment_files_bucket.s3_bucket_arn_output
    ]
  }

  statement {
    actions = [
      "s3:GetBucketLocation",
      "s3:ListAllMyBuckets"
    ]

    resources = [
      "*"
    ]
  }
}

# Create read/write iam policy for abacus-sap-payment-files s3 bucket
resource "aws_iam_policy" "s3_read_write_policy" {
  name   = "S3-${var.environment}-${var.bucket_name}-read-write-policy"
  policy = data.aws_iam_policy_document.s3_abacus_sap_payment_files_bucket_s3_read_write_policy.json
}

# Create S3 object lock retention policy document.
data "aws_iam_policy_document" "s3_abacus_sap_payment_files_bucket_lock_retention_policy_document" {
  statement {
    effect = "Deny"
    actions = [
      "s3:PutObjectRetention",
    ]

    resources = [
      "${module.s3_abacus_sap_payment_files_bucket.s3_bucket_arn_output}/*",
      ]
      condition {
        test     = "NumericLessThan"
        values   = [10]
        variable = "s3:object-lock-remaining-retention-days"
      }
    }
}

# Create S3 object lock retention policy.
resource "aws_iam_policy" "s3_abacus_sap_payment_files_bucket_lock_retention_policy" {
  name = "S3-${var.environment}-${var.bucket_name}-lock-retention-policy"
  policy = data.aws_iam_policy_document.s3_abacus_sap_payment_files_bucket_lock_retention_policy_document.json
}

# S3 IAM policy document for SME SAP tenant user
data "aws_iam_policy_document" "s3_sme_sap_tenant_user_readwrite_policy_document" {
  statement {
    actions = [
      "s3:GetBucketLocation",
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_abacus_sap_payment_files_bucket.s3_bucket_arn_output}/*",
    ]
  }

  statement {
    actions = [
      "s3:ListBucket",
    ]

    resources = [
      module.s3_abacus_sap_payment_files_bucket.s3_bucket_arn_output,
    ]
  }

  statement {
    actions = [
      "s3:PutObject",
    ]

    resources = [
      "${module.s3_abacus_sap_payment_files_bucket.s3_bucket_arn_output}/${var.sme_sap_payment_response_folder}/*",
    ]
  }
}

resource "aws_iam_policy" "s3_sme_sap_tenant_user_readwrite_policy" {
  name   = "S3-${var.environment}-${var.bucket_name}-sme-sap-tenant-user-readwrite-policy"
  policy = data.aws_iam_policy_document.s3_sme_sap_tenant_user_readwrite_policy_document.json
}