# Invoke lambda policy
data "aws_iam_policy_document" "invoke_lambda_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      module.lambda_create_altafonte_user.lambda_arn,
    ]
  }
}

# Assume role policy
data "aws_iam_policy_document" "jenkins_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

# Jenkins agent will assume this role to invoke the lambda
resource "aws_iam_role" "jenkins_invoke_role" {
  name               = "${var.environment}-${var.service_name}-role"
  assume_role_policy = data.aws_iam_policy_document.jenkins_assume_role_policy.json
  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.service_name
    terraformed        = true
  }
}

# Attach invoke lambda policy to role
resource "aws_iam_role_policy" "invoke_lambda_policy" {
  name   = "${var.environment}-${var.service_name}-invoke-lambda-policy"
  role   = aws_iam_role.jenkins_invoke_role.id
  policy = data.aws_iam_policy_document.invoke_lambda_policy_document.json
}