provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/asset-storage/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

data "aws_cloudfront_origin_access_identities" "origin_access_identities" {
  comments = [
    "access-identity-${var.environment}-asset-storage.s3.amazonaws.com",
  ]
}

data "aws_iam_policy_document" "asset_storage_bucket_policy" {
  dynamic "statement" {
    for_each = data.aws_cloudfront_origin_access_identities.origin_access_identities.iam_arns
    content {
      effect    = "Allow"
      actions   = ["s3:GetObject"]
      resources = ["${module.asset_storage_bucket.s3_bucket_arn_output}/*"]
      principals {
        type        = "AWS"
        identifiers = [statement.value]
      }
    }
  }
}

# Note: the module can create a policy
module "asset_storage_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.9.0"

  env                             = var.environment
  bucket_name                     = var.service_name
  s3_custom_read_only_policy_name = "S3-qa-asset-storage-RO"
  application_family              = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  bucket_policy_overrides = [data.aws_iam_policy_document.asset_storage_bucket_policy.json]

  block_public_access = false
}