data "aws_iam_policy_document" "lambda_assets_image_encoding_policy" {
  # checkov:skip=CKV_AWS_111:Ensure IAM policies does not allow write access without constraints
  statement {
    effect = "Allow"
    actions = [
      "s3:ListAllMyBuckets"
    ]
    resources = [
      "*"
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "s3:ListBucket"
    ]
    resources = [
      data.aws_s3_bucket.orcd_raw_assets.arn,
      data.aws_s3_bucket.orcd_mezzanine_assets.arn,
      data.aws_s3_bucket.asset_storage.arn
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "s3:GetObject",
      "s3:GetObjectAcl"
    ]
    resources = [
      "${data.aws_s3_bucket.orcd_raw_assets.arn}/*"
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "s3:GetBucketAcl",
      "s3:GetObject",
      "s3:GetObjectAcl",
      "s3:GetObjectVersion",
      "s3:GetObjectVersionAcl",
      "s3:PutObject",
      "s3:PutObjectAcl",
      "s3:PutObjectVersionAcl"
    ]
    resources = [
      "${data.aws_s3_bucket.orcd_mezzanine_assets.arn}/*",
      "${data.aws_s3_bucket.asset_storage.arn}/*"
    ]
  }
}

# Create assets-image-encoding IAM policy
resource "aws_iam_policy" "lambda_assets_image_encoding_policy" {
  name   = "${var.environment}-${var.lambda_service_name}-image-encoding-policy"
  policy = data.aws_iam_policy_document.lambda_assets_image_encoding_policy.json
}

module "image_encoding_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git?ref=1.0.1"

  environment_name = var.environment
  service_name     = "${var.lambda_service_name}-image-encoding"
}

module "lambda_assets_image_encoding" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.9"

  environment         = var.environment
  application_family  = var.application_family
  use_container_image = true
  lambda_name         = "${var.lambda_service_name}-image-encoding"
  lambda_description  = "Encodes images"


  lambda_function_environment_variables = {
    Environment                = var.environment
    SENTRY_DSN                 = module.sentry_lambda_assets_image_encoding.sentry_key_dsn_public_output
    OUTPUT_BUCKET_NAME         = data.aws_s3_bucket.orcd_mezzanine_assets.id
    PREVIEW_OUTPUT_BUCKET_NAME = data.aws_s3_bucket.asset_storage.id
    EXPECTED_BUCKET_OWNER      = data.aws_caller_identity.current.account_id
  }

  lambda_function_timeout                        = "300"
  lambda_function_memory_size                    = "3072"
  vpc_enabled                                    = true
  vpc_id                                         = module.vpc_info.vpc_id
  vpc_subnet_ids                                 = module.vpc_info.default_private_subnet_ids
  lambda_function_reserved_concurrent_executions = local.max_concurrency
  datadog_advanced_enabled                       = true
  datadog_enabled                                = true
  iam_managed_policy_attachments = [
    aws_iam_policy.lambda_assets_image_encoding_policy.arn,
    module.image_encoding_owsrequest.policy_arn_output
  ]
}

module "sentry_lambda_assets_image_encoding" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  service_name       = "${var.lambda_service_name}-image-encoding-v2" # v2 to differentiate from old sentry project"
  application_family = var.application_family
}

module "datadog_lambda_assets_image_encoding" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.10.9"

  environment                       = var.environment
  service_name                      = "${var.lambda_service_name}-image-encoding"
  lambda_invocation_monitor_enabled = false
  lambda_error_monitor_enabled      = true
  notification_endpoints            = var.notification_endpoints
}