# Asset transcoding state machine.

locals {
  lambda_arns = {
    audio_validation_lambda_arn            = module.lambda_assets_audio_validation.lambda_arn
    image_validation_lambda_arn            = module.lambda_image_validation.lambda_arn
    acknowledge_lambda_arn                 = module.lambda_assets_acknowledge.lambda_arn
    encoding_route_lambda_arn              = module.lambda_assets_encoding_route.lambda_arn
    image_encoding_lambda_arn              = module.lambda_assets_image_encoding.lambda_arn
    error_reporting_lambda_arn             = module.lambda_assets_error_reporting.lambda_arn
    trigger_spatial_transcoding_lambda_arn = module.lambda_assets_trigger_spatial_transcoding.lambda_arn
  }

  state_machine_definition = templatefile("${path.module}/${var.state_machine_definition_file}", {
    acknowledge_lambda_arn                        = local.lambda_arns["acknowledge_lambda_arn"]
    encoding_route_lambda_arn                     = local.lambda_arns["encoding_route_lambda_arn"]
    audio_validation_lambda_arn                   = local.lambda_arns["audio_validation_lambda_arn"]
    image_validation_lambda_arn                   = local.lambda_arns["image_validation_lambda_arn"]
    image_encoding_lambda_arn                     = local.lambda_arns["image_encoding_lambda_arn"]
    error_reporting_lambda_arn                    = local.lambda_arns["error_reporting_lambda_arn"]
    trigger_spatial_transcoding_lambda_arn        = local.lambda_arns["trigger_spatial_transcoding_lambda_arn"]
    spatial_audio_validation_queue_url            = aws_sqs_queue.spatial_audio_validation.url
    spatial_audio_validation_task_timeout_seconds = local.spatial_audio_validation_message_processing_timeout_minutes * 60
    spatial_audio_validation_heartbeat_seconds    = local.spatial_audio_validation_heartbeat_seconds
  })
}

# Policy document for lambda invocation initiated by the state machine.
data "aws_iam_policy_document" "assume_role_for_states_policy" {
  statement {
    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type = "Service"

      identifiers = [
        "states.${var.aws_region}.amazonaws.com",
      ]
    }
  }
}

data "aws_iam_policy_document" "lambda_invoke_policy" {
  statement {
    actions   = ["lambda:InvokeFunction"]
    resources = [for arn in local.lambda_arns : arn]
  }

  statement {
    actions   = ["sqs:SendMessage"]
    resources = [aws_sqs_queue.spatial_audio_validation.arn]
  }
}

# State machine role
resource "aws_iam_role" "sfn_role" {
  name               = "${var.environment}-${var.service_name}-states-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_for_states_policy.json
}

# Policy that gives the state machine role permission to invoke lambdas
resource "aws_iam_role_policy" "sfn_role_policy" {
  name   = "${var.environment}-${var.service_name}-sfn-role-policy"
  role   = aws_iam_role.sfn_role.id
  policy = data.aws_iam_policy_document.lambda_invoke_policy.json
}

# Step Function cloudwatch logs permission policy
data "aws_iam_policy_document" "sfn_log_event_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      "${aws_cloudwatch_log_group.sfn_log_group.arn}:*",
    ]

    actions = [
      "logs:CreateLogStream",
      "logs:PutLogEvents",
    ]
  }

  statement {
    effect = "Allow"
    resources = [
      "*",
    ]

    actions = [
      "logs:CreateLogDelivery",
      "logs:DeleteLogDelivery",
      "logs:DescribeLogGroups",
      "logs:DescribeResourcePolicies",
      "logs:GetLogDelivery",
      "logs:ListLogDeliveries",
      "logs:PutResourcePolicy",
      "logs:UpdateLogDelivery",
    ]
  }
}

resource "aws_iam_policy" "sfn_log_event_policy" {
  name        = "${var.environment}-${var.service_name}-sfn-log-policy"
  description = "${var.environment}-${var.service_name}-sfn-log-policy"
  policy      = data.aws_iam_policy_document.sfn_log_event_policy_document.json
}

resource "aws_iam_role_policy_attachment" "sfn_log_event_policy_attachment" {
  role       = aws_iam_role.sfn_role.name
  policy_arn = aws_iam_policy.sfn_log_event_policy.arn
}

data "aws_iam_policy_document" "kms_key_policy_document" {
  # checkov:skip=CKV_AWS_109:It is a KMS key policy, so it applies only to a specific key.
  # checkov:skip=CKV_AWS_111:Same as above.

  # Statement from default KMS key policy
  statement {
    sid    = "Enable IAM policies"
    effect = "Allow"
    principals {
      type        = "AWS"
      identifiers = ["arn:aws:iam::${data.aws_caller_identity.current.account_id}:root"]
    }
    actions   = ["kms:*"]
    resources = ["*"]
  }

  statement {
    sid    = "Allow use of the key by Cloudwatch logs"
    effect = "Allow"
    principals {
      type        = "Service"
      identifiers = ["logs.${var.aws_region}.amazonaws.com"]
    }
    actions = [
      "kms:Encrypt*",
      "kms:Decrypt*",
      "kms:ReEncrypt*",
      "kms:GenerateDataKey*",
      "kms:Describe*",
    ]
    resources = ["*"]
    condition {
      test     = "ArnEquals"
      variable = "kms:EncryptionContext:aws:logs:arn"
      values = [
        "arn:aws:logs:${var.aws_region}:${data.aws_caller_identity.current.account_id}:log-group:${var.environment}-${var.service_name}-sfn-log-group"
      ]
    }
  }
}

# KMS key for logging encryption
resource "aws_kms_key" "kms_key" {
  description             = "${var.environment}-${var.service_name}-snf-kms-key"
  enable_key_rotation     = true
  deletion_window_in_days = 30
  policy                  = data.aws_iam_policy_document.kms_key_policy_document.json
  tags                    = local.tags
}

resource "aws_kms_alias" "kms_alias" {
  name          = "alias/${var.environment}-${var.service_name}-sfn-kms-key"
  target_key_id = aws_kms_key.kms_key.key_id
}

resource "aws_cloudwatch_log_group" "sfn_log_group" {
  name              = "${var.environment}-${var.service_name}-sfn-log-group"
  retention_in_days = 365
  kms_key_id        = aws_kms_key.kms_key.arn
  tags              = local.tags
}

resource "aws_cloudwatch_log_subscription_filter" "sfn_datadog_lambda_log_filter" {
  name            = "${var.environment}-${var.service_name}-log-group-subscription-filter"
  log_group_name  = aws_cloudwatch_log_group.sfn_log_group.name
  filter_pattern  = ""
  destination_arn = data.aws_lambda_function.datadog_lambda_function.arn
  distribution    = "ByLogStream"
}

resource "aws_sfn_state_machine" "state_machine" {
  # checkov:skip=CKV_AWS_284:We don't use X-Ray.

  name       = "${var.environment}-${var.service_name}"
  role_arn   = aws_iam_role.sfn_role.arn
  definition = local.state_machine_definition
  tags       = local.tags

  logging_configuration {
    log_destination        = "${aws_cloudwatch_log_group.sfn_log_group.arn}:*"
    include_execution_data = true
    level                  = "ERROR"
  }

  tracing_configuration {
    enabled = false
  }
}

module "datadog_sfn_dashboard" {
  source             = "git@github.com:theorchard/terraform-datadog.git//modules/step-function?ref=6.10.9"
  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family
  statemachine_arn   = aws_sfn_state_machine.state_machine.arn

  failed_execution_message_log_monitor = {
    enabled        = true
    log_group_name = aws_cloudwatch_log_group.sfn_log_group.name
  }
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.escalation_notification_endpoints
}