provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/awal/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}


# prod-ddex-ingester bucket policy document
data "aws_s3_bucket" "qa_ddex_ingester_bucket" {
  bucket = "${var.environment}-ddex-ingester"
}

data "aws_iam_policy_document" "awal_s3_bucket_policy_document" {
statement {
    sid       = ""
    effect    = "Allow"
    resources = [
      "${data.aws_s3_bucket.qa_ddex_ingester_bucket.arn}/*",
      "${data.aws_s3_bucket.qa_ddex_ingester_bucket.arn}/awal_ddex/*",
    ]

    actions = [
      "s3:GetObject",
      "s3:GetObjectAcl",
      "s3:ListBucket",
      "s3:PutObject",
      "s3:PutObjectAcl",
    ]
  }

  statement {
    sid       = ""
    effect    = "Allow"
    resources = [
      data.aws_s3_bucket.qa_ddex_ingester_bucket.arn
    ]
    actions   = ["s3:GetBucketLocation"]
  }

  statement {
    sid       = ""
    effect    = "Allow"
    resources = [
      data.aws_s3_bucket.qa_ddex_ingester_bucket.arn
    ]
    actions   = ["s3:ListBucket"]

    condition {
      test     = "StringLike"
      variable = "s3:prefix"

      values = [
        "awal_ddex/",
        "awal_ddex*",
      ]
    }
  }
}

# Create policy for read-write access to the S3 bucket
resource "aws_iam_policy" "s3_awal_read_write_policy" {
  name   = "S3-${var.environment}-${var.service_name}-ddex-ingester-read-write-policy"
  policy = data.aws_iam_policy_document.awal_s3_bucket_policy_document.json
}

# Create IAM user
# resource "aws_iam_user" "iam_user" {
#   name = "${var.environment}-${var.service_name}-user"
#   tags = {
#     role        = "service-user"
#     terraformed = true
#   }
# }

# Attach IAM policies to IAM user
# resource "aws_iam_user_policy_attachment" "qa_awal_user_ddex_ingester_bucket_policy_attachment" {
#   policy_arn = aws_iam_policy.s3_awal_read_write_policy.arn
#   user       = aws_iam_user.iam_user.name
# }

# resource "aws_iam_user_policy_attachment" "iam_user_policy_attachment" {
#   user       = aws_iam_user.iam_user.name
#   count      = length(var.iam_policy_arn)
#   policy_arn = var.iam_policy_arn[count.index]
# }

module "s3_bucket" {
    source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.15.7"

    env                                 = var.environment
    bucket_name                         = var.bucket_name
    s3_read_only_policy                 = true
    application_family                  = "integrations"
    enable_guardduty_malware_protection = true

    apply_server_side_encryption_by_default = {

      sse_algorithm     = "AES256"
    }
}

module "datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/s3?ref=6.16.2"

  environment                       = var.environment
  application_family                = "integrations"
  service_name                      = var.bucket_name
  teams                             = ["integrations"]
  notification_endpoints            = "@devops-internal-alerts"
  escalation_notification_endpoints = "@devops-internal-alerts"

  dashboard_configuration = {
    enabled                       = false
    show_advanced_storage_metrics = false
    show_replication_metrics      = false
    show_standard_storage_metrics = false
  }

  guardduty_malware_monitor_configuration = {
    enabled = true
  }
}

data "aws_iam_policy_document" "s3_awal_data_integration_read_write_policy" {
  statement {
    actions = [
      "s3:GetBucketLocation",
      "s3:GetObject*",
      "s3:ListBucket",
      "s3:PutObject*",
      "s3:DeleteObject*",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/*"
    ]
  }

  statement {
    actions = [
      "s3:ListBucket",
    ]

    resources = [
      module.s3_bucket.s3_bucket_arn_output
    ]
  }
}

# Create policy for read-write access to the S3 bucket
resource "aws_iam_policy" "s3_read_write_policy" {
  name   = "S3-${var.environment}-${var.bucket_name}-data-integration-read-write-policy"
  policy = data.aws_iam_policy_document.s3_awal_data_integration_read_write_policy.json
}

data "aws_route53_zone" "awal" {
  name         = var.domain_name
  private_zone = false
}

resource "aws_acm_certificate" "tls_cert" {
  # checkov:skip=CKV2_AWS_71: Ensure AWS ACM Certificate domain name does not include wildcards
  domain_name               = "*.${data.aws_route53_zone.awal.name}"
  subject_alternative_names = [data.aws_route53_zone.awal.name]
  validation_method         = "DNS"

  options {
    certificate_transparency_logging_preference = "ENABLED"
  }

  tags = {
    environment  = var.environment
    service_name = var.service_name
    terraformed  = "true"
  }

  lifecycle {
    create_before_destroy = true
  }
}

resource "aws_route53_record" "dns_validation_record" {
  for_each = {
    for validation_object in aws_acm_certificate.tls_cert.domain_validation_options : validation_object.domain_name => {
      name   = validation_object.resource_record_name
      record = validation_object.resource_record_value
      type   = validation_object.resource_record_type
    }
  }

  allow_overwrite = true
  name            = each.value.name
  records         = [each.value.record]
  ttl             = 60
  type            = each.value.type
  zone_id         = data.aws_route53_zone.awal.zone_id
}

resource "aws_acm_certificate_validation" "certificate_validation" {
  certificate_arn         = aws_acm_certificate.tls_cert.arn
  validation_record_fqdns = [for record in aws_route53_record.dns_validation_record : record.fqdn]
}

# Add WAF for Cloudfront distribution
module "cdn_waf" {
  source            = "git@github.com:theorchard/terraform-aws-waf.git//?ref=2.0.0"
  environment       = var.environment
  service_name      = var.service_name
  aws_region        = var.aws_region
  acl_scope         = "CLOUDFRONT"
  count_waf_enabled = false
  block_waf_enabled = true
}