data "aws_iam_policy_document" "bulk-asset-upload-invoke-policy" {
  statement {
    effect = "Allow"
    actions = [
      "states:StartExecution",
      "states:ListExecutions",
      "states:GetExecutionHistory",
      "states:UpdateStateMachine",
      "states:DescribeStateMachine"
    ]
    resources = [
      "arn:aws:states:${var.region}:${data.aws_caller_identity.current.account_id}:stateMachine:${var.environment}-bulk-assets-ingester-sfn"
    ]
  }
  statement {
    effect = "Allow"
    actions = [
      "states:StopExecution",
      "states:DescribeExecution",
      "states:DescribeStateMachineForExecution"
    ]
    resources = [
      "arn:aws:states:${var.region}:${data.aws_caller_identity.current.account_id}:execution:${var.environment}-bulk-assets-ingester-sfn:*",
    ]
  }
}

# Assume role policy used by Jenkins scheduler agent role
data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-task-agent",
      ]
    }
  }
}

# SFN invoke policy.
resource "aws_iam_policy" "bulk_asset_upload_invoke_policy" {
  name   = "SFN-${var.environment}-bulk-asset-upload-invoke-policy"
  policy = data.aws_iam_policy_document.bulk-asset-upload-invoke-policy.json
}

# Jenkins agents will assume this role in order to invoke the machine
resource "aws_iam_role" "jenkins_invoke_role" {
  name               = "${var.environment}-bulk-asset-upload-jenkins-invoke-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

# Attach SFN invoke policy to Jenkins role.
resource "aws_iam_role_policy_attachment" "bulk_asset_upload_invoke_policy_attachment" {
  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = aws_iam_policy.bulk_asset_upload_invoke_policy.arn
}