data "aws_iam_policy_document" "common_lambda_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      module.s3_bulk_metadata_ingester_bucket.s3_bucket_arn_output
    ]
    actions = [
      "s3:ListBucket"
    ]
  }

  statement {
    sid    = ""
    effect = "Allow"
    resources = [
      "${module.s3_bulk_metadata_ingester_bucket.s3_bucket_arn_output}/*"
    ]

    actions = [
      "s3:GetObject",
      "s3:GetObjectAcl",
      "s3:HeadObject",
      "s3:PutObject",
    ]
  }
}

resource "aws_iam_policy" "common_lambda_policy" {
  name        = "${var.environment}-${var.service_name}-common-lambda-policy"
  description = "Common bulk-metadata-ingester lambda policy"
  policy      = data.aws_iam_policy_document.common_lambda_policy_document.json
}

data "aws_iam_policy_document" "delete_locks_lambda_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      "${module.s3_bulk_metadata_ingester_bucket.s3_bucket_arn_output}/locks/*"
    ]

    actions = [
      "s3:DeleteObject",
      "s3:DeleteObjectVersion",
    ]
  }
}

resource "aws_iam_policy" "delete_locks_lambda_policy" {
  name        = "${var.environment}-${var.service_name}-delete-locks-lambda-policy"
  description = "Delete locks bulk-metadata-ingester lambda policy"
  policy      = data.aws_iam_policy_document.delete_locks_lambda_policy_document.json
}

# Create policy to get secrets
data "aws_iam_policy_document" "secrets_manager_lambda_policy_document" {
  statement {
    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds",
    ]

    resources = [
      "arn:aws:secretsmanager:${var.region}:${data.aws_caller_identity.current.id}:secret:${var.environment}/${var.service_name}/",
      "arn:aws:secretsmanager:${var.region}:${data.aws_caller_identity.current.id}:secret:${var.environment}/${var.service_name}/*",
    ]
  }

}

resource "aws_iam_policy" "secrets_manager_lambda_policy" {
  name   = "${var.environment}-${var.service_name}-secrets-manager-policy"
  policy = data.aws_iam_policy_document.secrets_manager_lambda_policy_document.json
}