module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/content_review/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}


module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

data "aws_route53_zone" "networking_route53_zone" {
  provider = aws.networking

  name = "theorchard.io"
}

data "aws_caller_identity" "current" {}

data "aws_secretsmanager_secret" "rds_master_username" {
  name = "qa/content_review/rds_master_username"
}

data "aws_secretsmanager_secret_version" "rds_master_username" {
  secret_id = data.aws_secretsmanager_secret.rds_master_username.id
}

data "aws_secretsmanager_secret" "rds_master_password" {
  name = "qa/content_review/rds_master_password"
}

data "aws_secretsmanager_secret_version" "rds_master_password" {
  secret_id = data.aws_secretsmanager_secret.rds_master_password.id
}

module "content_review_rds" {
  source = "git@github.com:theorchard/terraform-rds.git//?ref=6.3.3"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family

  enabled_cloudwatch_logs_exports           = ["audit", "error", "general"]
  rds_cluster_instance_class                = "db.r6g.large"
  rds_cluster_instance_count                = "1"
  rds_engine_version                        = "8.0.mysql_aurora.3.05.2"
  rds_master_username                       = data.aws_secretsmanager_secret_version.rds_master_username.secret_string
  rds_master_password                       = data.aws_secretsmanager_secret_version.rds_master_password.secret_string
  rds_availability_zones                    = ["us-east-1a", "us-east-1c"]
  rds_db_subnet_group_name                  = "prod-orchard-private-subnet-group"
  rds_db_cluster_parameter_group_name       = "aurora-mysql80sync"
  rds_cluster_instance_parameter_group_name = "default.aurora-mysql8.0"
  rds_performance_insights_enabled          = false
  additional_tags                           = var.additional_tags

  custom_kms_key_enabled = false

  vpc_id          = module.vpc_info.vpc_id
  route53_zone_id = data.aws_route53_zone.route53_zone.zone_id
}

module "content_review_rds_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/rds?ref=6.13.4"

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family

  notification_endpoints            = var.monitor_notification_endpoint
  escalation_notification_endpoints = var.monitor_notification_endpoint
}

resource "aws_route53_record" "content_review_rds_cname" {
  zone_id = data.aws_route53_zone.route53_zone.zone_id
  name    = "qa-db-content-review"
  type    = "CNAME"
  ttl     = "300"
  records = [module.content_review_rds.rds_cluster_endpoint]
}

resource "aws_route53_record" "content_review_rds_cname_networking" {
  provider = aws.networking

  zone_id = data.aws_route53_zone.networking_route53_zone.zone_id
  name    = "qa-db-content-review"
  type    = "CNAME"
  ttl     = "300"
  records = [module.content_review_rds.rds_cluster_endpoint]
}

module "es_datadog_integration" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/open_search?ref=6.13.4"

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family

  notification_endpoints            = var.monitor_notification_endpoint
  escalation_notification_endpoints = var.monitor_notification_endpoint

  critical_number_5XX = 5

  monitor_enabled = false
}

module "content_review_match_audio_match_dynamodb_table" {
  source             = "git@github.com:theorchard/terraform-dynamodb.git//?ref=3.3.1"
  env                = var.environment
  table_name         = "${replace(var.service_name, "-", "_")}_match_audio_match"
  hash_key           = "asset_final_id"
  application_family = var.application_family
  use_on_demand      = true

  attribute = [
    {
      name = "asset_final_id"
      type = "N"
    }
  ]
}