module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/cypress-worker/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_iam_policy_document" "cypress_worker_task_policy" {
  statement {
    actions = [
      "ec2:DescribeSecurityGroups",
      "ecs:DescribeClusters",
      "ecs:DescribeTasks",
      "ecs:DescribeTaskDefinition",
      "ecs:ListTasks",
      "ecs:ListTaskDefinitions",
    ]
    effect = "Allow"

    resources = [
      "*",
    ]
  }

  statement {
    actions = [
      "ecs:RunTask",
      "ecs:StartTask",
    ]

    resources = [
      "arn:aws:ecs:*:${data.aws_caller_identity.current.account_id}:cluster/${var.environment}-${var.service_name}",
      "arn:aws:ecs:*:${data.aws_caller_identity.current.account_id}:task-definition/${var.environment}-${var.service_name}:*"
    ]
  }

  statement {
    actions = [
      "iam:PassRole",
    ]
    effect = "Allow"
    resources = [
      "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/${var.environment}-${var.service_name}-role",
      "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/${var.environment}-${var.service_name}-task-execution-role*",
      "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/${var.environment}-${var.service_name}-task-role"
    ]
  }
}

data "aws_iam_policy_document" "cypress_worker_assume_role_policy_document" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

resource "aws_iam_role" "cypress_worker_role" {
  name               = "${var.environment}-cypress-worker-role"
  assume_role_policy = data.aws_iam_policy_document.cypress_worker_assume_role_policy_document.json
  tags = {
    environment        = var.environment
    terraformed        = "true"
    application_family = var.application_family
  }
}

resource "aws_iam_policy" "cypress_worker_fargate_tasks_policy" {
  name   = "Task-${var.environment}-${var.service_name}-run-task-policy"
  policy = data.aws_iam_policy_document.cypress_worker_task_policy.json

  tags = {
    environment        = var.environment
    terraformed        = "true"
    application_family = var.application_family
  }
}
resource "aws_iam_role_policy_attachment" "cypress_worker_fargate_tasks_policy_attachment" {
  role       = aws_iam_role.cypress_worker_role.name
  policy_arn = aws_iam_policy.cypress_worker_fargate_tasks_policy.arn
}

data "aws_iam_policy_document" "cypress_worker_s3_bucket_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "s3:GetBucketLocation",
      "s3:GetObject*",
      "s3:ListBucket",
      "s3:PutObject*",
    ]
    resources = [
      "arn:aws:s3:::${var.config_s3_bucket}",
      "arn:aws:s3:::${var.config_s3_bucket}/*",
      "arn:aws:s3:::${var.environment}-neighbouring-rights",
      "arn:aws:s3:::${var.environment}-neighbouring-rights/*",
      "arn:aws:s3:::${var.environment}-encoding-direct-delivery-physical-location-9",
      "arn:aws:s3:::${var.environment}-encoding-direct-delivery-physical-location-9/*",
      "arn:aws:s3:::${var.environment}-orcdbucket",
      "arn:aws:s3:::${var.environment}-orcdbucket/qa-statement-attachments",
      "arn:aws:s3:::${var.environment}-orcdbucket/qa-statement-attachments/*",
      "arn:aws:s3:::${var.environment}-statement-detail-exports",
      "arn:aws:s3:::${var.environment}-statement-detail-exports/*",
      "arn:aws:s3:::${var.environment}-orcdbucket/qa-per-label-statement-attachments",
      "arn:aws:s3:::${var.environment}-orcdbucket/qa-per-label-statement-attachments/*",
      "arn:aws:s3:::prod-orcd-ftp",
      "arn:aws:s3:::prod-orcd-ftp/ftp/qa_vector_test/*",
      "arn:aws:s3:::qa-orcd-raw-assets",
      "arn:aws:s3:::qa-orcd-raw-assets/*",
    ]
  }
  statement {
    effect = "Allow"
    actions = [
      "s3:DeleteObject",
      "s3:DeleteObject*"
    ]
    resources = [
      "arn:aws:s3:::${var.environment}-neighbouring-rights/contributions/*",
      "arn:aws:s3:::${var.environment}-encoding-direct-delivery-physical-location-9/*",
      "arn:aws:s3:::${var.environment}-orcdbucket/qa-statement-attachments/*",
      "arn:aws:s3:::${var.config_s3_bucket}",
      "arn:aws:s3:::${var.config_s3_bucket}/*",
    ]
  }
}

data "aws_iam_policy_document" "cypress_worker_secrets_manager_policy" {
  statement {
    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds",
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/cypress-configs/",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/cypress-configs/*",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/cucumber-cypress-tests/",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/cucumber-cypress-tests/*",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/cucumber-cypress-tests-*/M2M_JWT_ACCESS_TOKEN",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/cucumber-cypress-tests-*/M2M_JWT_ACCESS_TOKEN*",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/e2e-test-secrets/user-data/*",
      #     Both environments need access to the user-data prod and qa user data secrets
      "arn:aws:secretsmanager:*:*:secret:prod/e2e-test-secrets/user-data/*",
    ]
  }

  statement {
    actions = [
      "secretsmanager:GetRandomPassword",
    ]

    resources = [
      "*",
    ]
  }
}

# dynamoDB access

data "aws_iam_policy_document" "cypress_dynamoDb_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "dynamodb:Query",
      "dynamodb:Scan",
      "dynamodb:DeleteItem",
    ]

    resources = [
      "arn:aws:dynamodb:us-east-1:437795906767:table/qa_statement_attachments_success",
      "arn:aws:dynamodb:us-east-1:437795906767:table/qa-accounting-statement-export",
      "arn:aws:dynamodb:us-east-1:437795906767:table/qa_statement_attachments_error",
      "arn:aws:dynamodb:us-east-1:437795906767:table/ows-accounting-owsrequest"
    ]
  }
}

data "aws_lambda_function" "lambda-vector-ready-deliveries" {
  function_name = "${var.environment}-lambda-vector-ready-deliveries"
}

data "aws_lambda_function" "lambda-vector-throttler" {
  function_name = "${var.environment}-lambda-vector-throttler"
}

data "aws_iam_policy_document" "cypress_labda_access_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "lambda:InvokeFunction",
    ]
    resources = [
      data.aws_lambda_function.lambda-vector-ready-deliveries.arn,
      data.aws_lambda_function.lambda-vector-throttler.arn,
    ]
  }
}

# Create IAM group cypress-worker.
resource "aws_iam_group" "cypress_worker_iam_group" {
  name = "cypress-worker"
}

# Reuse IAM cucumber-tests user.
resource "aws_iam_group_membership" "cypress_worker_iam_group_membership" {
  name = "cypress_worker_iam_group_membership"
  users = [
    "cucumber-tests",
  ]

  group = aws_iam_group.cypress_worker_iam_group.name
}

# Create secrets manager policy for cypress-configs
resource "aws_iam_policy" "cypress_worker_secrets_manager_policy" {
  name   = "Secretsmanager-${var.environment}-${var.service_name}-secrets-manager-policy"
  policy = data.aws_iam_policy_document.cypress_worker_secrets_manager_policy.json

  tags = {
    terraformed        = true
    application_family = var.application_family
  }
}
resource "aws_iam_policy" "s3_cypress_worker_read_write_policy" {
  name   = "S3-${var.environment}-${var.service_name}-read-write-policy"
  policy = data.aws_iam_policy_document.cypress_worker_s3_bucket_policy_document.json

  tags = {
    terraformed        = true
    application_family = var.application_family
  }
}

resource "aws_iam_policy" "cypress_dynamoDb_policy" {
  name   = "DynamoDb-${var.environment}-${var.service_name}-read-write-policy"
  policy = data.aws_iam_policy_document.cypress_dynamoDb_policy_document.json

  tags = {
    terraformed        = true
    application_family = var.application_family
  }
}

resource "aws_iam_policy" "cypress_lambda_policy" {
  name   = "${var.environment}-${var.service_name}-lambda-access-policy"
  policy = data.aws_iam_policy_document.cypress_labda_access_policy_document.json

  tags = {
    terraformed        = true
    application_family = var.application_family
  }
}


resource "aws_iam_group_policy_attachment" "iam_group_policy_attachment" {
  for_each = toset([
    "arn:aws:iam::${data.aws_caller_identity.current.account_id}:policy/S3-${var.environment}-${var.service_name}-read-write-policy",
    "arn:aws:iam::${data.aws_caller_identity.current.account_id}:policy/Secretsmanager-${var.environment}-${var.service_name}-secrets-manager-policy",
    "arn:aws:iam::${data.aws_caller_identity.current.account_id}:policy/Task-${var.environment}-${var.service_name}-run-task-policy",
  ])

  policy_arn = each.value
  group      = aws_iam_group.cypress_worker_iam_group.name
}

module "cypress_secrets" {
  source                         = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = "SNOWFLAKE_KEY"
  application_family             = var.application_family
  secret_recovery_window_in_days = 30
}

module "cypress_worker_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.4.1"

  providers = {
    aws.dns = aws.networking
  }

  environment          = var.environment
  service_name         = var.service_name
  aws_region           = var.aws_region
  commit_sha           = "latest"
  container_port       = 9000
  task_type            = "worker"
  desired_task_count   = 0
  task_cpu             = 4096
  task_memory          = 12288
  maximum_capacity     = 200
  minimum_capacity     = 0
  vpc_id               = module.vpc_info.vpc_id
  application_family   = var.application_family
  health_check_command = "$(npm bin)/cypress verify"

  iam_managed_policy_attachments = [
    aws_iam_policy.cypress_dynamoDb_policy.arn,
    aws_iam_policy.cypress_worker_secrets_manager_policy.arn,
    aws_iam_policy.s3_cypress_worker_read_write_policy.arn,
    aws_iam_policy.cypress_worker_fargate_tasks_policy.arn,
    aws_iam_policy.cypress_lambda_policy.arn
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
  ]
}

module "cypress_worker_fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.16.2"

  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  service_4xx_monitor_enabled       = false
  service_5xx_monitor_enabled       = false
  notification_endpoints            = "@slack-cucumber-cypress-development"
  escalation_notification_endpoints = "@slack-cucumber-cypress-development"
  application_family                = var.application_family
}

module "m2m_secrets" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//modules/auth0m2m?ref=1.6.1"

  for_each           = toset(var.function_names)
  environment        = var.environment
  service_name       = "${var.service_name}-${each.value}"
  application_family = var.application_family
}