module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/dbt-accounting/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

# IAM policy to make M2M API calls to other OWS services.
data "aws_iam_policy" "ows_machine_to_machine_policy" {
  name = "SecretsManager-${var.environment}-ows-machine-to-machine-policy"
}

module "dbt_accounting_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
}

module "dbt_accounting_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.3.1"

  providers = {
    aws.dns = aws.networking
  }

  application_family                    = var.application_family
  environment                           = var.environment
  service_name                          = var.service_name
  aws_region                            = var.aws_region
  non_ecr_image                         = "437795906767.dkr.ecr.us-east-1.amazonaws.com/dbt-accounting"
  commit_sha                            = "latest"
  task_type                             = "worker"
  container_port                        = "8080"
  desired_task_count                    = 0
  minimum_capacity                      = 0
  maximum_capacity                      = 0
  task_cpu                              = 1024
  task_memory                           = 2048
  vpc_id                                = module.vpc_info.vpc_id
  fargate_service_subnets               = module.vpc_info.default_private_subnet_ids
  fargate_spot_capacity_provider_weight = 100
  task_placement_failure_alert_enabled  = true

  iam_managed_policy_attachments = [
    aws_iam_policy.secrets_manager_policy.arn,
    data.aws_iam_policy.ows_machine_to_machine_policy.arn,
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      SNOWFLAKE_ACCOUNT = "delphi.us-east-1"
    },
    {
      SNOWFLAKE_DATABASE = "ROYALTY_ACCOUNTING"
    },
    {
      SNOWFLAKE_USER = "QA_ACCOUNTING_DBT_SCHEDULER"
    },
    {
      SNOWFLAKE_ROLE = "QA_ACCOUNTING_DBT_SCHEDULER"
    },
    {
      SNOWFLAKE_WAREHOUSE = "QA_ACCOUNTING_DBT_WAREHOUSE"
    },
    {
      SNOWFLAKE_SCHEMA = "QA"
    },
    {
      DBT_TARGET = "qa"
    },
    {
      DBT_FULL_REFRESH = "true"
    },
    {
      DBT_SELECT_MODELS = "ledger_summary_dbt account_statement_periods_dbt combined_expenses_dbt combined_expenses_by_artist_dbt expenses_by_subaccount_dbt combined_advances_dbt combined_adjustments_dbt combined_adjustments_by_type_dbt combined_payments_dbt"
    },
    {
      DBT_EXCLUDE_MODELS = "abacus_fact_sales_unified_dbt workstation_fact_sales_unified_dbt revenue_distro_dbt"
    },
  ]

  secrets = [
    {
      SNOWFLAKE_PRIVATE_KEY = "${var.environment}/${var.service_name}/SNOWFLAKE_PRIVATE_KEY"
    },
  ]
}

module "fargate_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.18.2"
  environment                       = var.environment
  service_name                      = var.service_name
  environment_type                  = "fargate"
  service_4xx_monitor_enabled       = false
  service_5xx_monitor_enabled       = false
  healthy_tasks_monitor_enabled     = false
  application_family                = var.application_family
  notification_endpoints            = "@slack-moneyhub-alerts"
  escalation_notification_endpoints = "@slack-moneyhub-alerts"
}

resource "aws_cloudwatch_log_group" "dbt_accounting_sm_logs" {
  name              = "/aws/vendedlogs/states/${var.environment}-${var.service_name}-sm-Logs"
  retention_in_days = 365
}

resource "aws_sfn_state_machine" "dbt_accounting_run_state_machine" {
  # checkov:skip=CKV_AWS_284:Ensure State Machine has X-Ray tracing enabled
  name     = "${var.environment}-${var.service_name}-sm"
  role_arn = aws_iam_role.step_func_ecs_runner_role.arn

  definition = local.state_machine_definition

  logging_configuration {
    log_destination        = "${aws_cloudwatch_log_group.dbt_accounting_sm_logs.arn}:*"
    include_execution_data = true
    level                  = "ALL"
  }

  tags = {
    env              = var.environment
    service          = var.service_name
    DD_TRACE_ENABLED = true
  }

  depends_on = [aws_iam_role_policy.step_func_logging]
}