provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/dbt-analytics-pipeline/terraform.tfstate"
    region  = "us-east-1"
    encrypt = true
  }
}

module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  additional_tags = {
    terraformed = "true"
  }
}

module "secrets" {
  source             = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each           = toset(var.secrets_manager_secret_names)
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
  application_family = var.application_family
}

# Create secrets manager policy for lambda to access secrets
data "aws_iam_policy_document" "dbt_analytics_pipeline_secrets_manager_policy" {
  statement {
    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds"
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/*",
    ]
  }
}

resource "aws_iam_policy" "dbt_analytics_pipeline_secrets_manager_policy" {
  name   = "Secretsmanager-${var.environment}-${var.service_name}-secrets-manager-policy"
  policy = data.aws_iam_policy_document.dbt_analytics_pipeline_secrets_manager_policy.json
}

import {
  to = aws_iam_user.dbt_analytics_pipeline_user
  id = "qa-dbt-analytics"
}

resource "aws_iam_user" "dbt_analytics_pipeline_user" {
  name = "qa-dbt-analytics"
  tags = {
    terraformed = true
    role        = "service-user"
    application = var.application_family
  }
}

# Allow user to fetch secrets
resource "aws_iam_user_policy_attachment" "dbt_analytics_pipeline_manager_policy_attachment" {
  user       = aws_iam_user.dbt_analytics_pipeline_user.name
  policy_arn = aws_iam_policy.dbt_analytics_pipeline_secrets_manager_policy.arn
}