provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/dbt-shopify-global-schema-scheduler/terraform.tfstate"
    region  = "us-east-1"
    encrypt = true
  }
}

module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
  additional_tags = {
    terraformed = "true"
  }
}

module "secrets" {
  source             = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each           = toset(var.secrets_manager_secret_names)
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
  application_family = var.application_family
}

# Create secrets manager policy for Jenkins agent to access secrets
data "aws_iam_policy_document" "dbt_shopify_global_schema_scheduler_secrets_manager_policy" {
  statement {
    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds"
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/*",
    ]
  }
}

resource "aws_iam_policy" "dbt_shopify_global_schema_scheduler_secrets_manager_policy" {
  name   = "Secretsmanager-${var.environment}-${var.service_name}-secrets-manager-policy"
  policy = data.aws_iam_policy_document.dbt_shopify_global_schema_scheduler_secrets_manager_policy.json
}

# Assume role policy used by Jenkins scheduler agent role
data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-task-agent",
      ]
    }
  }
}

# Jenkins agent will assume this role in order to access SecretsManager
resource "aws_iam_role" "dbt_shopify_global_schema_deploy_role" {
  name               = "${var.environment}-${var.service_name}-deploy-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

# Allow role to fetch secrets
resource "aws_iam_role_policy_attachment" "dbt_shopify_global_schema_scheduler_manager_policy_attachment" {
  role       = aws_iam_role.dbt_shopify_global_schema_deploy_role.name
  policy_arn = aws_iam_policy.dbt_shopify_global_schema_scheduler_secrets_manager_policy.arn
}