module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/documents/evaluate-tax-eligibility/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

#################################
#
# lambda configuration
#
##################################
module "lambda_documents_evaluate_tax_eligibility" {
  source                   = "git@github.com:theorchard/terraform-lambda.git//?ref=5.3.0"
  environment              = var.environment
  lambda_name              = var.lambda_name
  lambda_description       = "Evaluate a Payee's tax_eligibility"
  datadog_enabled          = var.datadog_enabled
  datadog_advanced_enabled = var.datadog_advanced_enabled

  application_family = var.application_family

  lambda_function_provisioned_concurrent_executions = var.lambda_provisioned_concurrent_executions
  lambda_function_timeout                           = "300"
  use_container_image                               = true

  vpc_id                    = module.vpc_info.vpc_id
  vpc_subnet_ids            = module.vpc_info.default_private_subnet_ids
  vpc_create_security_group = true
  zappa_s3_policy_enabled   = false


  lambda_function_environment_variables = {
    Environment = var.environment
  }

  msk_event_enabled                     = true
  event_source_mapping_msk_cluster_name = var.trigger_msk_cluster_name
  event_source_mapping_msk_cluster_uuid = var.trigger_msk_cluster_uuid
  kafka_topics = [
    "graphql.subscription.abacusAccountPayeeVATInfoSaved",
    "graphql.subscription.abacusAccountPayeePayoneerWFormCollected",
    "graphql.subscription.abacusAccountTaxInfoUpdated",
    "graphql.subscription.abacusAccountPayeePayoneerReleased",
    "graphql.subscription.abacusAccountPayeeResyncEligibility",
    "graphql.subscription.abacusAccountPayeeResyncPaymentReadiness",
    "event.payee.programMove"
  ]

  cloudwatch_event_enabled = true
  cloudwatch_event_rules = [
    {
      name     = "${var.service_name}-reject-expired-us-event"
      schedule = "cron(0 5 * * ? *)"
      input    = jsonencode({ "rejectExpiredUSTaxForms" = true })
    },
    {
      name     = "${var.service_name}-reject-expired-es-event"
      schedule = "cron(0 6 * * ? *)"
      input    = jsonencode({ "rejectExpiredESTaxForms" = true })
    },
  ]
}

module "lambda_documents_evaluate_tax_eligibility_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = var.lambda_name
}

# create datadog dashboards.
module "datadog_lambda_documents_evaluate_tax_eligibility" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.17.1"

  environment                       = var.environment
  service_name                      = var.lambda_name
  lambda_invocation_monitor_enabled = false

  notification_endpoints            = "@slack-The_Orchard-documents-public"
  escalation_notification_endpoints = "@slack-The_Orchard-documents-public"
}

module "lambda_documents_evaluate_tax_eligibility_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  platform           = "javascript"
  service_name       = var.lambda_name
  teams              = [var.environment]
  application_family = var.application_family
}

resource "datadog_monitor" "expiration_job_monitor" {
  name    = "${var.environment}-${var.lambda_name} expiration job monitor"
  type    = "log alert"
  message = "{{log.message}}\nNotify: @slack-The_Orchard-documents-public"

  // This will match the substring for 2 jobs US and ES
  query = <<EOT
  logs("message:\"Tax Forms Expiration Job\" service:${var.lambda_name} environment:${var.environment}").index("main").rollup("count").last("5m") > 0
  EOT

  monitor_thresholds {
    critical = 0
  }

  include_tags      = true
  notify_no_data    = false
  renotify_interval = 0
  tags = [
    "environment:${var.environment}",
    "service_name:${var.service_name}",
    "application_family:${var.application_family}",
    "terraformed:true",
  ]
}