module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/documents/knr-payments-approve/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

module "s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.15.1"

  env                 = var.environment
  bucket_name         = var.s3_bucket_name
  acceleration_status = "Enabled"
  application_family  = var.application_family
  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  # CORS Rules
  bucket_cors_rule = [
    {
      allowed_headers = ["*"]
      allowed_methods = ["GET", "PUT", "POST"]
      allowed_origins = [
        "http://localhost:*",
      ]
      expose_headers  = ["ETag"]
      max_age_seconds = 3000
    }
  ]

  lifecycle_rules_options_noncurrent_version_transition = [
    {
      prefix        = ""
      enabled       = false
      days          = 35
      storage_class = "STANDARD_IA"
    }
  ]
}

data "aws_s3_bucket" "knr_payments_output_bucket" {
  bucket = "${var.environment}-lambda-documents-knr-payments"
}

data "aws_s3_bucket" "sap_payments_output_bucket" {
  bucket = "${var.environment}-abacus-sap-payment-files"
}

data "aws_kms_key" "sap_payments_bucket_kms_key" {
  key_id = "alias/${var.environment}_abacus_sap_payment_files"
}

data "aws_iam_policy_document" "s3_input_bucket_policy" {
  statement {
    effect = "Allow"

    actions = [
      "s3:HeadBucket",
      "s3:ListBucket",
      "s3:GetObjectVersion",
      "s3:GetObjectTagging",
      "s3:GetObjectVersionTagging",
      "s3:GetObject",
      "s3:GetObjectAcl",
      "s3:GetObjectVersionAcl",
      "s3:PutObject",
      "s3:PutObjectVersion",
      "s3:PutObjectTagging",
      "s3:PutObjectVersionTagging",
      "s3:PutObjectAcl",
      "s3:PutObjectVersionAcl",
      "s3:CopyObject"
    ]

    resources = [
      data.aws_s3_bucket.knr_payments_output_bucket.arn,
      "${data.aws_s3_bucket.knr_payments_output_bucket.arn}/*"
    ]
  }
}


resource "aws_iam_policy" "s3_input_bucket_policy" {
  name        = "S3-${data.aws_s3_bucket.knr_payments_output_bucket.id}-${var.service_name}-RW"
  description = "Read, Write access to lambda-documents knr-payments bucket"
  policy      = data.aws_iam_policy_document.s3_input_bucket_policy.json
}

data "aws_iam_policy_document" "s3_sap_bucket_policy" {
  statement {
    effect = "Allow"

    actions = [
      "s3:HeadBucket",
      "s3:ListBucket",
      "s3:ListObjects",
      "s3:GetObject",
      "s3:GetObjectTagging",
      "s3:GetObjectAcl",
      "s3:PutObject",
      "s3:PutObjectTagging",
      "s3:CopyObject",
      "s3:PutObjectAcl"
    ]

    resources = [
      data.aws_s3_bucket.sap_payments_output_bucket.arn,
      "${data.aws_s3_bucket.sap_payments_output_bucket.arn}/*"
    ]
  }
}

resource "aws_iam_policy" "s3_output_bucket_policy" {
  name        = "S3-${data.aws_s3_bucket.sap_payments_output_bucket.id}-${var.service_name}-RW"
  description = "Read, Write access to abacus-sap-files bucket"
  policy      = data.aws_iam_policy_document.s3_sap_bucket_policy.json
}

# IAM kms policy document for abacus-sap-payment-files s3 bucket
data "aws_iam_policy_document" "s3_sap_output_files_kms_key_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "kms:Encrypt",
      "kms:Decrypt",
      "kms:ReEncrypt*",
      "kms:GenerateDataKey*",
      "kms:DescribeKey"
    ]
    resources = [
      data.aws_kms_key.sap_payments_bucket_kms_key.arn
    ]
  }
}


resource "aws_iam_policy" "s3_sap_output_files_kms_key_policy" {
  name   = "KMS-${data.aws_s3_bucket.sap_payments_output_bucket.id}-${var.service_name}-encrypt-decrypt-policy"
  policy = data.aws_iam_policy_document.s3_sap_output_files_kms_key_policy_document.json
}

#################################
#
# lambda configuration
#
##################################
module "lambda_documents_knr_payments_approve" {
  source                   = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.1"
  environment              = var.environment
  lambda_name              = var.lambda_name
  lambda_description       = "Approve knr payments file by copying to approve bucket"
  datadog_enabled          = var.datadog_enabled
  datadog_advanced_enabled = var.datadog_advanced_enabled

  application_family = var.application_family

  lambda_function_provisioned_concurrent_executions = var.lambda_provisioned_concurrent_executions
  lambda_function_timeout                           = "300"
  use_container_image                               = true

  vpc_id                    = module.vpc_info.vpc_id
  vpc_subnet_ids            = module.vpc_info.default_private_subnet_ids
  vpc_create_security_group = true
  zappa_s3_policy_enabled   = false

  lambda_function_environment_variables = {
    Environment              = var.environment
    KNR_PAYMENTS_BUCKET_NAME = data.aws_s3_bucket.knr_payments_output_bucket.bucket
    SAP_BUCKET_NAME          = data.aws_s3_bucket.sap_payments_output_bucket.bucket
  }

  iam_managed_policy_attachments = [
    aws_iam_policy.s3_input_bucket_policy.arn,
    aws_iam_policy.s3_output_bucket_policy.arn,
    aws_iam_policy.s3_sap_output_files_kms_key_policy.arn
  ]
}

module "lambda_documents_knr_payments_approve_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = var.lambda_name
}

# create datadog dashboards.
module "datadog_lambda_documents_knr_payments_approve" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.16.0"

  environment                       = var.environment
  service_name                      = var.lambda_name
  lambda_invocation_monitor_enabled = false

  notification_endpoints            = "@slack-The_Orchard-documents-public"
  escalation_notification_endpoints = "@slack-The_Orchard-documents-public"
}

module "lambda_documents_knr_payments_approve_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  platform           = "javascript"
  service_name       = var.lambda_name
  teams              = [var.environment]
  application_family = var.application_family
}

# create invoke policy to allow jenkins to run job

data "aws_iam_policy_document" "knr_payments_approve_invoke_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "lambda:InvokeFunction",
      "lambda:GetFunction",
      "lambda:GetFunctionConfiguration",
      "lambda:GetPolicy",
      "lambda:GetAlias",
      "lambda:ListVersionsByFunction",
      "lambda:ListAliases",
      "lambda:GetFunctionEventInvokeConfig"
    ]
    resources = [
      module.lambda_documents_knr_payments_approve.lambda_arn
    ]
  }
}


data "aws_iam_policy_document" "jenkins_knr_payments_approve_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

resource "aws_iam_role" "knr_payments_approve_invoke_role" {
  name                  = "${var.environment}-knr-payments-approve-invoke-role"
  force_detach_policies = true
  assume_role_policy    = data.aws_iam_policy_document.jenkins_knr_payments_approve_assume_role_policy.json

  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.service_name
    terraformed        = "true"
  }
}

resource "aws_iam_policy" "knr_payments_approve_invoke_policy" {
  name   = "${var.environment}-knr-payments-aprove-invoke-policy"
  policy = data.aws_iam_policy_document.knr_payments_approve_invoke_policy_document.json

  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.service_name
    terraformed        = "true"
  }
}

resource "aws_iam_role_policy_attachment" "knr_payments_approve_invoke_policy_attachment" {
  role       = aws_iam_role.knr_payments_approve_invoke_role.name
  policy_arn = aws_iam_policy.knr_payments_approve_invoke_policy.arn
}