module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/documents/send-payments/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

#################################
#
# lambda configuration
#
##################################
module "lambda_documents_send_payments" {
  source                   = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.1"
  environment              = var.environment
  lambda_name              = var.lambda_name
  lambda_description       = "Send payments to Payoneer via ows-payee API"
  datadog_enabled          = var.datadog_enabled
  datadog_advanced_enabled = var.datadog_advanced_enabled

  application_family = var.application_family

  lambda_function_provisioned_concurrent_executions = var.lambda_provisioned_concurrent_executions
  lambda_function_timeout                           = "300"
  use_container_image                               = true

  vpc_id                    = module.vpc_info.vpc_id
  vpc_subnet_ids            = module.vpc_info.default_private_subnet_ids
  vpc_create_security_group = true
  zappa_s3_policy_enabled   = false


  lambda_function_environment_variables = {
    Environment = var.environment
  }
}

module "lambda_documents_send_payments_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = var.lambda_name
}

module "datadog_lambda_documents_send_payments" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.16.0"

  environment                       = var.environment
  service_name                      = var.lambda_name
  lambda_invocation_monitor_enabled = false

  notification_endpoints            = "@slack-The_Orchard-documents-public"
  escalation_notification_endpoints = "@slack-The_Orchard-documents-public"
}

module "lambda_documents_send_payments_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  platform           = "javascript"
  service_name       = var.lambda_name
  teams              = [var.environment]
  application_family = var.application_family
}

data "aws_iam_policy_document" "lambda_documents_send_payments_invoke_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "lambda:InvokeFunction"
    ]
    resources = [
      module.lambda_documents_send_payments.lambda_arn
    ]
  }
}

resource "aws_iam_policy" "lambda_documents_send_payments_invoke_policy" {
  name        = "${var.environment}-${var.lambda_name}-invoke-policy"
  description = "Policy for invoking ${var.lambda_name} lamdba"
  policy      = data.aws_iam_policy_document.lambda_documents_send_payments_invoke_policy_document.json
}