terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/fivetran/ows-assets/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "fivetran_group" "ows_assets" {
  id = "gentry_invitro"
}

data "aws_rds_cluster" "qa_ows_assets" {
  cluster_identifier = "${var.environment}-${var.service_name}"
}

resource "fivetran_connector" "qa_ows_assets_connector" {
  group_id = data.fivetran_group.ows_assets.id
  service  = "aurora"

  destination_schema {
    prefix = "qa_ows_assets"
  }

  config {
    host        = data.aws_rds_cluster.qa_ows_assets.endpoint
    port        = data.aws_rds_cluster.qa_ows_assets.port
    user        = "fivetran"
    database    = "ows_assets"
    tunnel_host = "fivetran.theorchard.io"
    tunnel_port = "2222"
    tunnel_user = "fivetran"
  }
}

resource "fivetran_connector_schedule" "qa_ows_dmp_connector_schedule" {
  connector_id   = fivetran_connector.qa_ows_assets_connector.id
  sync_frequency = 360
}

resource "fivetran_connector_schema_config" "main" {
  connector_id           = fivetran_connector.qa_ows_assets_connector.id
  schema_change_handling = "ALLOW_COLUMNS"
  schemas = {
    ows_assets = {
      enabled = true
      tables = { for table in var.ows_assets_tables_to_sync_to_snowflake : table => {
        enabled = true
      } }
    }
  }
}