provider "aws" {
  region = var.region
}

# This is the region of the failover bucket
provider "aws" {
  region = "us-west-2"
  alias  = "aws_us_west_2"
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/frontend-account360/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_route53_zone" "domain" {
  name         = var.domain_name
  private_zone = true
}

data "aws_s3_bucket" "bucket_primary" {
  bucket = "${var.environment}-orcd-cdn"
}

data "aws_s3_bucket" "bucket_failover" {
  bucket   = "${var.environment}-orcd-cdn-us-west01"
  provider = aws.aws_us_west_2
}

module "spa_environment" {
  # checkov:skip=CKV2_AWS_47:Rule requires the AWSManagedRulesAnonymousIpList to be enabled on the WAF, which blocks legitimate traffic.
  # checkov:skip=CKV_AWS_374:Ensure AWS CloudFront web distribution has geo restriction enabled.
  # skip_checkov: ORCD_AWS_3 - This check was skipped because <your reason here>
  # skip_checkov: CKV2_AWS_47 - This check was skipped because <your reason here>

  source = "git@github.com:theorchard/terraform-spa.git//?ref=1.4.1"
  providers = {
    aws.primary = aws
    aws.failover = aws.aws_us_west_2
  }

  environment                           = var.environment
  service_name                          = var.service_name_suffix
  application_family                    = var.application_family
  brand                                 = var.brand
  domain_name                           = var.domain_name
  default_root_object                   = "index.html"
  # Pick two buckets in different regions. In qa/prod these values do not typically need to be specified.
  custom_origin_primary_s3_bucket_name  = data.aws_s3_bucket.bucket_primary.id
  custom_origin_failover_s3_bucket_name = data.aws_s3_bucket.bucket_failover.id
  custom_logging_bucket = "prod-orcd-cloudfront-logs"
}

module "frontend_account360_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  environment        = var.environment
  platform           = "javascript"
  service_name       = var.frontend_service_name
  application_family = var.application_family
}

resource "aws_route53_record" "route53_record" {
  name    = var.service_name_suffix
  zone_id = data.aws_route53_zone.domain.zone_id
  type    = "CNAME"
  ttl     = "60"
  records = [module.spa_environment.cloudfront_distribution_domain_name]
}