provider "aws" {
  region = var.aws_region
}

provider "aws" {
  alias  = "failover"
  region = "us-west-2"
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/frontend-account360/sme/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_wafv2_web_acl" "waf" {
  name  = "${var.environment}-orcd-cloudfront-waf-block"
  scope = "CLOUDFRONT"
}

module "spa_environment" {
  # checkov:skip=CKV2_AWS_47:Rule requires the AWSManagedRulesAnonymousIpList to be enabled on the WAF, which blocks legitimate traffic.
  # checkov:skip=CKV_AWS_374: Ensure AWS CloudFront web distribution has geo restriction enabled.
  source = "git@github.com:theorchard/terraform-spa.git//?ref=1.4.1"
  providers = {
    aws.primary = aws
    aws.failover = aws.failover
  }

  environment                           = var.environment
  service_name                          = var.service_name
  application_family                    = var.application_family
  brand                                 = var.brand
  domain_name                           = var.domain_name
  default_root_object                   = "index-sme.html"
  custom_waf_name                       = data.aws_wafv2_web_acl.waf.name
}

data "cloudflare_zone" "cloudflare_cloudflare_zone" {
  filter = {
    name = var.domain_name
  }
}

resource "cloudflare_dns_record" "qa_sme_account360_cloudflare_record" {
   zone_id = data.cloudflare_zone.cloudflare_cloudflare_zone.id
   name    = "${var.service_name}.${var.domain_name}"
   ttl     = 1
   content   = module.spa_environment.cloudfront_distribution_domain_name
   type    = "CNAME"
   proxied = true
}