provider "aws" {
  region = var.aws_region
}

provider "aws" {
  alias  = "failover"
  region = "us-west-2"
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/frontend-audience-development/awal/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_route53_zone" "domain" {
  name         = var.domain_name
  private_zone = false
}

module "spa_environment" {
  # checkov:skip=CKV2_AWS_47:Rule requires the AWSManagedRulesAnonymousIpList to be enabled on the WAF, which blocks legitimate traffic.
  source = "git@github.com:theorchard/terraform-spa.git//?ref=1.4.0"
  providers = {
    aws.primary  = aws
    aws.failover = aws.failover
  }

  environment           = var.environment
  service_name          = var.service_name
  application_family    = var.application_family
  brand                 = var.brand
  domain_name           = var.domain_name
  custom_logging_bucket = "prod-orcd-cloudfront-logs"
  default_root_object   = "index-awal.html"
  additional_aliases = [
    "${var.subdomain_name}.${var.domain_name}",
  ]
  use_only_additional_aliases = true
  custom_waf_name             = "${var.environment}-${var.brand}-waf-block"
}

resource "aws_route53_record" "route53_record" {
  name    = var.subdomain_name
  zone_id = data.aws_route53_zone.domain.zone_id
  type    = "CNAME"
  ttl     = "60"
  records = [module.spa_environment.cloudfront_distribution_domain_name]
}