provider "aws" {
  region = var.aws_region
}

provider "aws" {
  alias  = "aws_us_west_2"
  region = "us-west-2"
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/frontend-audience-development/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_route53_zone" "domain" {
  name         = var.domain_name
  private_zone = true
}

data "aws_wafv2_web_acl" "waf" {
  name  = "${var.environment}-${var.service_name}-cloudfront-waf-block"
  scope = "CLOUDFRONT"
}

module "spa_environment" {
  # checkov:skip=CKV2_AWS_47:Rule requires the AWSManagedRulesAnonymousIpList to be enabled on the WAF, which blocks legitimate traffic.
  # checkov:skip=CKV_AWS_374:Ensure AWS CloudFront web distribution has geo restriction enabled.
  source = "git@github.com:theorchard/terraform-spa.git//?ref=1.4.1"
  providers = {
    aws.primary  = aws
    aws.failover = aws.aws_us_west_2
  }
  environment         = var.environment
  service_name        = var.service_name_suffix
  application_family  = var.application_family
  brand               = var.service_name
  domain_name         = var.domain_name
  default_root_object = "index.html"
  additional_aliases = [
    "audience.${var.domain_name}",
    "fansifter.${var.domain_name}",
  ]
  custom_logging_bucket = "prod-orcd-cloudfront-logs"
  custom_waf_name       = data.aws_wafv2_web_acl.waf.name
}

module "frontend_audience_development_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  environment        = var.environment
  platform           = "javascript"
  service_name       = local.frontend_service_name
  application_family = var.application_family
}

resource "aws_route53_record" "route53_record" {
  name    = "fansifter"
  zone_id = data.aws_route53_zone.domain.zone_id
  type    = "CNAME"
  ttl     = "60"
  records = [module.spa_environment.cloudfront_distribution_domain_name]
}